shvcall 3.10.2

CLI utility to invoke remote SHV RPC calls
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47

{
  description = "Rust implementation of headless Silicon Heaven applications";

  outputs = {
    self,
    systems,
    nixpkgs,
  }: let
    inherit (builtins) head match readFile;
    inherit (nixpkgs.lib) genAttrs;
    forSystems = genAttrs (import systems);
    withPkgs = func: forSystems (system: func self.legacyPackages.${system});

    package = {rustPlatform}:
      rustPlatform.buildRustPackage {
        pname = "shvcall-rs";
        version = head (
          match ".*\nversion[ ]*=[ ]*\"([^\"]+)\"\n.*" (readFile ./Cargo.toml)
        );

        src = ./.;
        cargoLock = {
          lockFile = ./Cargo.lock;
        };
        doCheck = true;

        meta = with nixpkgs.lib; {
          description = "CLI utility to invoke remote SHV RPC calls";
          homepage = "https://github.com/silicon-heaven/shvcall-rs/";
          license = licenses.mit;
          mainProgram = "shvcall";
        };
      };
  in {
    overlays.default = final: _: {
      shvcall-rs = final.callPackage package {};
    };

    packages = withPkgs (pkgs: {default = pkgs.shvcall-rs;});

    legacyPackages =
      forSystems (system:
        nixpkgs.legacyPackages.${system}.extend self.overlays.default);

    formatter = withPkgs (pkgs: pkgs.alejandra);
  };
}