shuvarie 0.2.2

Blazingly fast AI coding TUI for chivalrous people
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98

{
  description = "Blazingly fast AI coding TUI for chivalrous people";

  inputs = {
    nixpkgs.url = "git+https://github.com/NixOS/nixpkgs?ref=nixos-unstable";
    selune = {
      url = "git+https://github.com/chardoncs/selune?ref=main";
      flake = false;
    };
  };

  outputs =
    {
      self,
      nixpkgs,
      selune,
    }:
    let
      systems = [
        "x86_64-linux"
        "aarch64-linux"
        "x86_64-darwin"
        "aarch64-darwin"
      ];
      forAllSystems = nixpkgs.lib.genAttrs systems;
      version =
        (builtins.fromTOML (builtins.readFile ./Cargo.toml)).workspace.package.version
        + "+${self.shortRev or self.dirtyShortRev or "unknown"}";
    in
    {
      packages = forAllSystems (
        system:
        let
          pkgs = nixpkgs.legacyPackages.${system};
        in
        rec {
          shuvarie = pkgs.rustPlatform.buildRustPackage {
            pname = "shuvarie";
            inherit version;

            src = self;

            cargoLock.lockFile = ./Cargo.lock;

            cargoBuildFlags = [
              "--bin"
              "shuvarie"
            ];

            postUnpack = ''
              rm -rf "$sourceRoot/vendor/selune"
              mkdir -p "$sourceRoot/vendor"
              cp -rL ${selune} "$sourceRoot/vendor/selune"
            '';
            meta = {
              description = "Blazingly fast AI coding TUI for chivalrous people";
              homepage = "https://github.com/shuvarie/shuvarie";
              license = pkgs.lib.licenses.mit;
              mainProgram = "shuvarie";
              platforms = systems;
            };
          };

          default = shuvarie;
        }
      );

      apps = forAllSystems (system: {
        default = {
          type = "app";
          program = "${self.packages.${system}.shuvarie}/bin/shuvarie";
        };
      });

      devShells = forAllSystems (
        system:
        let
          pkgs = nixpkgs.legacyPackages.${system};
        in
        {
          default = pkgs.mkShell {
            packages = with pkgs; [
              cargo
              clippy
              git
              just
              rust-analyzer
              rustc
              rustfmt
            ];
            env.RUST_SRC_PATH = "${pkgs.rustPlatform.rustLibSrc}";
          };
        }
      );

      formatter = forAllSystems (system: nixpkgs.legacyPackages.${system}.nixfmt);
    };
}