shelly-shell 0.5.4

A Rust based Unix style shell with a typed and structured language syntax.
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88

#!/usr/bin/env shelly

import std::terminal::{ readline }
import std::terminal::readline::{ Editor }

error struct CommandError
{
    pub message: String
}

fn help()
{
    echo "*
        help           Show these commands
        status         Show the current name
        name NEW_NAME  Change the name in the prompt
        quit           Exit (or press Ctrl+D)
        *"
    ()
}

fn main(): () | ErrorValue
{
    let $name = "demo"

    fn dispatch($line: String): () | CommandError
    {
        match $line
        {
            "help" => { help },
            "status" => { echo "Current name: ${name}" },
            _ =>
            {
                if ($line != "name") && !($line.starts_with "name ")
                {
                    return CommandError(message: "Unknown command: ${line}. Try help.")
                }
                let $new_name = ($line.strip_prefix "name").trim
                if $new_name == ""
                {
                    return CommandError(message: "Usage: name NEW_NAME")
                }
                $name = $new_name
            },
        }
        ()
    }

    let $editor = Editor(
        prompt: readline::Prompt(
            left: fn(): String
                {
                    "${name}> "
                },
            right: "help for commands",
            continuation: "... "),
        complete: (readline::words ["help", "status", "name", "quit"]))

    try
    {
        for $input in $editor.lines
        {
            let $line = $input.trim
            if $line == "quit"
            {
                break
            }
            if $line == ""
            {
                continue
            }
            try
            {
                dispatch $line
            }
            catch ($error: CommandError)
            {
                echo $error.message
            }
        }
    }
    finally
    {
        $editor.close
    }
}

main