serde-bool 0.1.2

Single-side boolean deserializers
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54

_list:
    @just --list

# Clippy check workspace.
clippy:
    cargo clippy --workspace --no-default-features
    cargo clippy --workspace --all-features
    cargo hack --feature-powerset --depth=3 clippy --workspace

# Run workspace test suite.
test toolchain="":
    cargo {{ toolchain }} test
    RUSTDOCFLAGS="-D warnings" cargo {{ toolchain }} doc --workspace --no-deps --all-features

# Run workspace test suite using MSRV.
test-msrv:
    @just test +1.56.1

# Run workspace test suite, capturing coverage.
test-coverage toolchain="":
    @just test-coverage-codecov {{ toolchain }}
    @just test-coverage-lcov {{ toolchain }}

# Run workspace test suite, capturing coverage info in Codecov format.
test-coverage-codecov toolchain="":
    cargo {{ toolchain }} llvm-cov --workspace --all-features --codecov --output-path codecov.json

# Run workspace test suite, capturing coverage info in Lcov format.
test-coverage-lcov toolchain="":
    cargo {{ toolchain }} llvm-cov --workspace --all-features --lcov --output-path lcov.info

# Build workspace documentation.
doc:
    RUSTDOCFLAGS="--cfg=docsrs" cargo +nightly doc --no-deps --workspace --all-features

# Build workspace documentation, open it, and watch for changes.
doc-watch:
    RUSTDOCFLAGS="--cfg=docsrs" cargo +nightly doc --no-deps --workspace --all-features --open
    cargo watch -- RUSTDOCFLAGS="--cfg=docsrs" cargo +nightly doc --no-deps --workspace --all-features

# Check project.
check:
    just --unstable --fmt --check
    npx -y prettier --check '**/*.{md,yml,yaml}'
    taplo lint
    cargo +nightly fmt -- --check
    @just clippy

# Format project.
fmt:
    just --unstable --fmt
    npx -y prettier --write '**/*.{md,yml,yaml}'
    taplo format
    cargo +nightly fmt