seqtable 0.2.0

High-performance FASTQ sequence counter
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47

{inputs, ...}: {
  perSystem = {
    self',
    pkgs,
    lib,
    ...
  }: let
    rustToolchain = pkgs.rust-bin.stable.latest.default;
    craneLib = (inputs.crane.mkLib pkgs).overrideToolchain rustToolchain;

    src = craneLib.cleanCargoSource ../.;

    commonArgs = {
      inherit src;
      pname = "seqtable";
      version = "0.2.0";
      nativeBuildInputs = with pkgs; [pkg-config cmake];
    };

    # Build only dependencies (cached separately)
    cargoArtifacts = craneLib.buildDepsOnly commonArgs;
  in {
    packages = {
      seqtable = craneLib.buildPackage (commonArgs
        // {
          inherit cargoArtifacts;
          doCheck = pkgs.stdenv.buildPlatform.canExecute pkgs.stdenv.hostPlatform;
          meta = with lib; {
            description = "High-performance parallel FASTQ sequence counter";
            license = licenses.mit;
            platforms = platforms.linux ++ platforms.darwin;
            mainProgram = "seqtable";
          };
        });

      default = self'.packages.seqtable;
    };

    checks = {
      clippy = craneLib.cargoClippy (commonArgs
        // {
          inherit cargoArtifacts;
          cargoClippyExtraArgs = "--all-targets --all-features -- -D warnings";
        });
    };
  };
}