sd-switch 0.6.2

A systemd unit reload/restart utility for Home Manager
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122

{
  description = "SD Switch";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";
    crane.url = "github:ipetkov/crane?ref=v0.21.0";
    pre-commit-hooks = {
      url = "github:cachix/git-hooks.nix";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  outputs =
    {
      self,
      nixpkgs,
      crane,
      pre-commit-hooks,
    }:
    let
      systems = [
        "aarch64-darwin"
        "aarch64-linux"
        "x86_64-darwin"
        "x86_64-linux"
      ];

      forAllSystems =
        f:
        nixpkgs.lib.genAttrs systems (
          system:
          f rec {
            inherit system;
            pkgs = nixpkgs.legacyPackages.${system};
            lib = pkgs.lib;
            craneLib = crane.mkLib pkgs;

            src = lib.cleanSourceWith {
              src = craneLib.path ./.;
              filter = path: type: lib.hasInfix "/testdata/" path || craneLib.filterCargoSources path type;
            };

            commonArgs = {
              inherit src;
              meta = {
                description = "Systemd unit switcher for Home Manager";
                homepage = "https://git.sr.ht/~rycee/sd-switch";
                changelog = "https://git.sr.ht/~rycee/sd-switch/tree/master/item/CHANGELOG.md";
                license = lib.licenses.gpl3Plus;
                platforms = lib.platforms.linux;
                mainProgram = "sd-switch";
              };
            };

            cargoArtifacts = craneLib.buildDepsOnly commonArgs;

            package = craneLib.buildPackage (commonArgs // { inherit cargoArtifacts; });

            pre-commit-check = pre-commit-hooks.lib.${system}.run {
              inherit src;
              hooks = {
                nixfmt-rfc-style.enable = true;
                rustfmt.enable = true;
              };
            };
          }
        );
    in
    {
      packages = forAllSystems (
        p:
        let
          integrationTestPackages =
            let
              tests = import ./tests/integration {
                pkgs = import nixpkgs {
                  inherit (p) system;
                  overlays = [ (final: prev: { sd-switch = p.package; }) ];
                };
              };
              renameTestPkg = n: p.lib.nameValuePair "integration-test-${n}";
            in
            p.lib.mapAttrs' renameTestPkg tests;
        in
        {
          default = p.package;

          # Package for CI only. Used to cache the dependencies.
          _deps = p.cargoArtifacts;
        }
        // integrationTestPackages
      );

      checks = forAllSystems (p: {
        inherit (p) pre-commit-check;

        clippy =
          with p;
          craneLib.cargoClippy (
            commonArgs
            // {
              inherit cargoArtifacts;
              cargoClippyExtraArgs = "--all-targets -- --deny warnings";
            }
          );
      });

      devShells = forAllSystems (p: {
        default = p.craneLib.devShell {
          checks = self.checks.${p.system};

          inputsFrom = [ p.package ];
          packages = with p.pkgs; [
            cargo-audit
            cargo-outdated
          ];

          shellHook = p.pre-commit-check.shellHook;
        };
      });
    };
}