script 0.5.0

barebones http scripting
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154

grammar = { SOI ~ (route_definition | function_def | not_found | wildcard)* ~ EOI }

route_definition = { 
	 route_attr? ~ function_def
}

function_def = { 
	 route_name ~ ("(" ~ parameters? ~ ")")? ~ block
}

wildcard = {
	 "*" ~ block
}

not_found = {
	 "404" ~ block
}

route_attr = { 
	 "#" ~ "[" ~ "route" ~ "(" ~ string_literal ~ ")" ~ 
	 ("," ~ cfg_block)? ~ 
	 "]" 
}

cfg_block = { 
	 "cfg" ~ "(" ~ cfg_entries ~ ")"
}

cfg_entries = {
	 cfg_entry ~ ("," ~ cfg_entry)* ~ ","?
}

cfg_entry = {
	 identifier ~ "=" ~ (boolean | string_literal | number)
}

route_name = @{ (ASCII_ALPHA | "_") ~ (ASCII_ALPHANUMERIC | "_" | "/" | ".")* }

parameters = { parameter ~ ("," ~ parameter)* ~ ","? }

parameter = @{ identifier }

block = {
	 "{" ~ statement* ~ "}"
}

statement = {
	 let_statement |
	 expression_statement |
	 assignment |
	 if_statement |
	 for_statement |
	 while_statement |
	 return_statement |
	 block
}

let_statement = {
	 "let" ~ identifier ~ ("=" ~ expression)? ~ ";"
}

expression_statement = {
	 expression ~ ";"?
}

assignment = {
	 identifier ~ "=" ~ expression ~ ";"
}

if_statement = {
	 "if" ~ expression ~ block ~ ("else" ~ (if_statement | block))?
}

for_statement = {
	 "for" ~ identifier ~ "in" ~ expression ~ block
}

while_statement = {
	 "while" ~ expression ~ block
}

return_statement = {
	 "return" ~ expression? ~ ";"?
}

expression = { 
	 logical_expr
}

logical_expr = {
	 comparison_expr ~ (("&&" | "||") ~ comparison_expr)*
}

comparison_expr = {
	 arithmetic_expr ~ (("==" | "!=" | "<" | ">" | "<=" | ">=") ~ arithmetic_expr)*
}

arithmetic_expr = {
	 term ~ (("+" | "-") ~ term)*
}

term = {
	 factor ~ (("*" | "/" | "%") ~ factor)*
}

factor = {
	 unary_expr |
	 "(" ~ expression ~ ")" |
	 call_chain |
	 object |
	 array |
	 literal
}

unary_expr = {
	 ("-" | "!") ~ factor
}

call_chain = {
	 (identifier | literal) ~
	 (
		  "::" ~ identifier |
		  "." ~ identifier |
		  arguments
	 )* ~
	 arguments?
}

arguments = {
	 "(" ~ (expression ~ ("," ~ expression)*)? ~ ","? ~ ")"
}

object = { 
	 "#{" ~ (object_entry ~ ("," ~ object_entry)*)? ~ ","? ~ "}"
}

object_entry = { (identifier | string_literal) ~ ":" ~ expression }

array = { 
	 "[" ~ (expression ~ ("," ~ expression)*)? ~ ","? ~ "]"
}

literal = { number | string_literal | boolean | object | array }

number = @{ "-"? ~ ASCII_DIGIT+ ~ ("." ~ ASCII_DIGIT+)? ~ ("e" ~ "-"? ~ ASCII_DIGIT+)? }

string_literal = @{ ("\"" ~ (!"\"" ~ ANY)* ~ "\"") | ("`" ~ (!"`" ~ ANY)* ~ "`") }

boolean = { "true" | "false" }

identifier = @{ (ASCII_ALPHA | "_") ~ (ASCII_ALPHANUMERIC | "_")* }

WHITESPACE = _{ " " | "\t" | "\n" | "\r" }
COMMENT = _{ "//" ~ (!"\n" ~ ANY)* | "/*" ~ (!"*/" ~ ANY)* ~ "*/" }