sccache 0.14.0

Sccache is a ccache-like tool. It is used as a compiler wrapper and avoids compilation when possible. Sccache has the capability to utilize caching in remote storage environments, including various cloud storage options, or alternatively, in local storage.
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108

{
  description = "sccache development environment and package";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-25.11";
    flake-utils.url = "github:numtide/flake-utils";
  };

  outputs = {
    self,
    nixpkgs,
    flake-utils,
  }: let
    cargoToml = builtins.fromTOML (builtins.readFile ./Cargo.toml);
    version = cargoToml.package.version;

    mkSccache = {
      final,
      pname,
      features ? [],
      description,
    }:
      final.rustPlatform.buildRustPackage {
        pname = pname;
        inherit version;

        src = ./.;

        cargoLock = {
          lockFile = ./Cargo.lock;
        };

        nativeBuildInputs = [final.pkg-config];
        buildInputs = [final.openssl];

        cargoBuildFlags =
          if features != []
          then [
            "--features"
            (builtins.concatStringsSep "," features)
          ]
          else [];

        doCheck = false;

        meta = with final.lib; {
          description = description;
          homepage = "https://github.com/mozilla/sccache";
          changelog = "https://github.com/mozilla/sccache/releases/tag/v${version}";
          license = licenses.asl20;
          mainProgram = "sccache";
        };
      };
  in
    flake-utils.lib.eachSystem
    [
      "x86_64-linux"
      "aarch64-linux"
      "x86_64-darwin"
      "aarch64-darwin"
      "i686-linux"
    ]
    (
      system: let
        pkgs = import nixpkgs {
          inherit system;
          overlays = [self.overlays.default];
        };
      in {
        packages = {
          default = pkgs.sccache;
          sccache = pkgs.sccache;
          sccache-dist = pkgs.sccache-dist;
        };

        devShells.default = pkgs.mkShell {
          name = "sccache-dev";

          buildInputs = with pkgs; [
            rustup
            openssl
            pkg-config
            gcc
          ];
        };

        formatter = pkgs.alejandra;
      }
    )
    // {
      overlays.default = final: prev: {
        sccache = mkSccache {
          inherit final;
          pname = "sccache";
          description = "Ccache with Cloud Storage";
        };
        sccache-dist = mkSccache {
          inherit final;
          pname = "sccache-dist";
          features = [
            "dist-client"
            "dist-server"
          ];
          description = "Ccache with Cloud Storage and Distributed Compilation";
        };
      };
    };
}