rust-expression 0.3.1

Calculator and solver for linear equations.
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31

int = { ("+" | "-")? ~ ASCII_DIGIT+ }
num = @{ int ~ ("." ~ ASCII_DIGIT*)? ~ (^"e" ~ int)? }

ident = _{ ASCII_ALPHA ~ ( ASCII_ALPHANUMERIC | "_" )* }

symbol = @{ ident }

operation = _{ add | subtract | multiply | divide | rem | power }
    add      = { "+" }
    subtract = { "-" }
    multiply = { "*" }
    divide   = { "/" }
    rem      = { "%" }
    power    = { "^" }

fun_call = { symbol ~ "(" ~ ( expr ~ ("," ~ expr)* )? ~ ")" }

expr = { term ~ (operation ~ term)* }
term = _{ num | fun_call | symbol | "(" ~ expr ~ ")" }

function = { symbol ~ "(" ~ ( symbol ~ ("," ~ symbol)* )? ~ ")" ~ ":=" ~ expr }

assignment = { symbol ~ ":=" ~ expr }

solvefor = { "solve" ~ expr ~ "=" ~ expr ~ "for" ~ symbol }

plot = { "plot" ~ symbol }

statement = _{ SOI ~ ( function | plot | solvefor | assignment | expr ) ~ EOI }

WHITESPACE = _{ " " | "\t" }