runic 1.1.0

Stupid string to duration converter
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105

// Input
// ...

Input = _{ SOI ~ Expr* ~ EOI }

WordExpr = _{
  ASCII_ALPHA+
}

Expr = _{
  WHITE_SPACE*
  ~ (AtTimeExpr | WordExpr | DurationExpr)
  ~ WHITE_SPACE*
}

// Duration
// ...

Hours = {
  "hour" ~ "s"?
  | "hr" ~ "s"?
  | "h"
}

Minutes = {
  "minute" ~ "s"?
  | "min" ~ "s"?
  | "m"
}

Seconds = {
  "second" ~ "s"?
  | "sec" ~ "s"?
  | "s"
}

Duration = {
  "-"?
  ~ ASCII_DIGIT*
  ~ ("." ~ ASCII_DIGIT*)?
}

DurationExpr = {
  Duration
  ~ WHITE_SPACE*
  ~ (Hours | Minutes | Seconds)
}

// At Time
// ...

AtHours = {
  ASCII_DIGIT+
}

AtMinutes = {
  ASCII_DIGIT+
}

TimeValue = _{
  AtHours
  ~ ":"?
  ~ AtMinutes?
}

Pm = { "PM" | "pm" }
Am = { "AM" | "am" }

AtTime = {
  TimeValue
  ~ (WHITE_SPACE* ~ (Am | Pm))?
}

AtTimeExpr = {
  "at"
  ~ WHITE_SPACE+
  ~ AtTime
  ~ (WHITE_SPACE+ ~ TimezoneLikeExpr)?
}

// Timezone
// ...

TimezonePositive = { "+" }
TimezoneNegative = { "-" }
TimezoneSign = _{ TimezonePositive | TimezoneNegative }
TimezoneUTCLiteral = _{ ^"utc" }

TimezoneHours = { ASCII_DIGIT{1,2} }
TimezoneHours2 = { ASCII_DIGIT{2} }
TimezoneMinutes = { ASCII_DIGIT{2} }
TimezoneLiteral = _{
  (!"0" ~ TimezoneHours ~ !":")
  | (TimezoneHours2 ~ ":"? ~ TimezoneMinutes)
}

TimezoneLikeExpr = {
  TimezoneUTCLiteral
  ~ (ASCII_DIGIT | "+" | "-" | ":")*
}

TimezoneExpr = {
  TimezoneUTCLiteral
  ~ (TimezoneSign ~ TimezoneLiteral)?
}