rue-compiler 0.8.4

A compiler for the Rue programming language.
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70

// merkle.rue by yakuhito

import tree_hash::{tree_hash_atom, tree_hash_pair};

export struct MerkleProof {
    path: Int,
    ...hashes: List<Bytes32>,
}

export fn calculate_merkle_root(
    path: Int,
    current_hash: Bytes32,
    additional_steps: List<Bytes32>,
) -> Bytes32 {
    if additional_steps is nil {
        return current_hash;
    }
    
    calculate_merkle_root(
        path >>> 1,
        tree_hash_pair(
            inline if path & 1 != 0 {
                additional_steps.first
            } else {
                current_hash
            },
            inline if path & 1 != 0 {
                current_hash
            } else {
                additional_steps.first
            }
        ),
        additional_steps.rest
    )
}

fn simplify_merkle_proof_after_leaf(
    leaf_hash: Bytes32,
    proof: MerkleProof,
) -> Bytes32 {
    if proof.hashes is nil {
        return leaf_hash;
    }

    simplify_merkle_proof_after_leaf(
        tree_hash_pair(
            inline if proof.path & 1 != 0 {
                proof.hashes.first
            } else {
                leaf_hash
            },
            inline if proof.path & 1 != 0 {
                leaf_hash
            } else {
                proof.hashes.first
            }
        ),
        MerkleProof {
            path: proof.path >>> 1,
            hashes: proof.hashes.rest
        }
    )
}

export inline fn simplify_merkle_proof(
    leaf: Bytes32,
    proof: MerkleProof,
) -> Bytes32 {
    simplify_merkle_proof_after_leaf(tree_hash_atom(leaf), proof)
}