rsjsonnet-lang 0.5.0

A Jsonnet evaluation library
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74

// This is the part of the standard library that is written in Jsonnet.

{
  abs(n)::
    assert self.isNumber(n) : "first argument of `std.abs` is expected to be number, got " + self.type(n);
    if n > 0 then n else -n,

  sign(n)::
    assert self.isNumber(n) : "first argument of `std.sign` is expected to be number, got " + self.type(n);
    if n > 0 then
      1
    else if n < 0 then
      -1
    else 0,

  max(a, b)::
    assert self.isNumber(a) : "first argument of `std.max` is expected to be number, got " + self.type(a);
    assert self.isNumber(b) : "second argument of `std.max` is expected to be number, got " + self.type(b);
    if a > b then a else b,

  min(a, b)::
    assert self.isNumber(a) : "first argument of `std.min` is expected to be number, got " + self.type(a);
    assert self.isNumber(b) : "second argument of `std.min` is expected to be number, got " + self.type(b);
    if a < b then a else b,

  clamp(x, minVal, maxVal)::
    assert self.isNumber(x) : "first argument of `std.clamp` is expected to be number, got " + self.type(x);
    assert self.isNumber(minVal) : "second argument of `std.clamp` is expected to be number, got " + self.type(minVal);
    assert self.isNumber(maxVal) : "third argument of `std.clamp` is expected to be number, got " + self.type(maxVal);
    if x < minVal then
      minVal
    else if x > maxVal then
      maxVal
    else
      x,

  round(x):: self.floor(x + 0.5),

  isEmpty(str):: self.length(str) == 0,

  manifestToml(value):: self.manifestTomlEx(value, "  "),

  manifestJson(value):: self.manifestJsonEx(value, "    "),

  manifestJsonMinified(value):: self.manifestJsonEx(value, "", "", ":"),

  lines(arr):: self.join("\n", arr + [""]),

  get(o, f, default=null, inc_hidden=true):: if self.objectHasEx(o, f, inc_hidden) then o[f] else default,

  objectHas(o, f):: self.objectHasEx(o, f, false),
  objectHasAll(o, f):: self.objectHasEx(o, f, true),

  objectFields(o):: self.objectFieldsEx(o, false),
  objectFieldsAll(o):: self.objectFieldsEx(o, true),

  objectValues(o):: [o[key] for key in self.objectFields(o)],
  objectValuesAll(o):: [o[key] for key in self.objectFieldsAll(o)],

  objectKeysValues(o):: [{ key: key, value: o[key] } for key in self.objectFields(o)],
  objectKeysValuesAll(o):: [{ key: key, value: o[key] } for key in self.objectFieldsAll(o)],

  xor(x, y):: x != y,
  xnor(x, y):: x == y,

  resolvePath(f, r)::
    local parts = self.split(f, "/");
    self.join("/", parts[:self.length(parts) - 1] + [r]),

  __array_less(arr1, arr2):: self.__compare_array(arr1, arr2) < 0,
  __array_less_or_equal(arr1, arr2):: self.__compare_array(arr1, arr2) <= 0,
  __array_greater(arr1, arr2):: self.__compare_array(arr1, arr2) > 0,
  __array_greater_or_equal(arr1, arr2):: self.__compare_array(arr1, arr2) >= 0,
}