revive-integration 1.2.0

revive compiler integration test cases
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.35;

/* runner.json
{
    "differential": true,
    "actions": [
        {
            "Instantiate": {
                "code": {
                    "Solidity": {
                        "contract": "ERC7201"
                    }
                }
            }
        }
    ]
}
*/

/// Tests the `erc7201` builtin introduced in solc 0.8.35.
/// Reference: https://eips.ethereum.org/EIPS/eip-7201
contract ERC7201 {
    /// Reference implementation of the ERC-7201 base slot formula in pure
    /// Solidity. Used to cross-check the builtin output.
    function referenceSlot(string memory id) internal pure returns (uint256) {
        return uint256(
            keccak256(bytes.concat(bytes32(uint256(keccak256(bytes(id))) - 1)))
                & ~bytes32(uint256(0xff))
        );
    }

    constructor() payable {
        // Compile-time path: literal argument, solc folds the result into a
        // numeric constant in the emitted Yul.
        assert(erc7201("example.main") == referenceSlot("example.main"));
        assert(
            erc7201("erc7201:openzeppelin.storage.Initializable")
                == referenceSlot("erc7201:openzeppelin.storage.Initializable")
        );
        assert(erc7201("") == referenceSlot(""));

        // Runtime path: non-literal argument, solc emits a Yul utility
        // function that performs the keccak256 hashes at runtime.
        string memory id = "example.main";
        assert(erc7201(id) == referenceSlot(id));

        string memory empty = "";
        assert(erc7201(empty) == referenceSlot(empty));

        // The two paths must agree.
        assert(erc7201("example.main") == erc7201(id));
    }
}