resharp-grep 0.1.0

a grep-like grep tool powered by the resharp regex engine
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80

{
  description = "resharp - grep powered by the RE# regex engine";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";
  };

  outputs = { self, nixpkgs }:
    let
      systems = [ "x86_64-linux" "aarch64-linux" "x86_64-darwin" "aarch64-darwin" ];
      forAllSystems = f: nixpkgs.lib.genAttrs systems (system: f {
        pkgs = nixpkgs.legacyPackages.${system};
      });
    in
    {
      packages = forAllSystems ({ pkgs }: {
        default = pkgs.rustPlatform.buildRustPackage {
          pname = "resharp";
          version = "0.1.0";
          src = pkgs.lib.cleanSource ./.;
          cargoLock.lockFile = ./Cargo.lock;

          nativeBuildInputs = [ pkgs.installShellFiles ];

          postInstall = ''
            ln -s $out/bin/resharp "$out/bin/re#"
            installShellCompletion --cmd resharp \
              --bash <($out/bin/resharp --completions bash) \
              --zsh <($out/bin/resharp --completions zsh) \
              --fish <($out/bin/resharp --completions fish)
          '';

          meta = {
            description = "grep tool powered by the resharp regex engine with intersection, complement, and lookarounds";
            license = pkgs.lib.licenses.mit;
            mainProgram = "resharp";
          };
        };

        aarch64-linux = pkgs.pkgsCross.aarch64-multiplatform.rustPlatform.buildRustPackage {
          pname = "resharp";
          version = "0.1.0";
          src = pkgs.lib.cleanSource ./.;
          cargoLock.lockFile = ./Cargo.lock;

          meta = {
            description = "grep tool powered by the resharp regex engine with intersection, complement, and lookarounds";
            license = pkgs.lib.licenses.mit;
            mainProgram = "resharp";
          };
        };

        windows = pkgs.pkgsCross.mingwW64.rustPlatform.buildRustPackage {
          pname = "resharp";
          version = "0.1.0";
          src = pkgs.lib.cleanSource ./.;
          cargoLock.lockFile = ./Cargo.lock;

          meta = {
            description = "grep tool powered by the resharp regex engine with intersection, complement, and lookarounds";
            license = pkgs.lib.licenses.mit;
            mainProgram = "resharp";
          };
        };
      });

      devShells = forAllSystems ({ pkgs }: {
        default = pkgs.mkShell {
          buildInputs = with pkgs; [
            cargo
            rustc
            clippy
            rustfmt
            ripgrep
            hyperfine
          ];
        };
      });
    };
}