repose-render-wgpu 0.30.3

Repose wgpu handler
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101

struct Globals {
    ndc_to_px: vec2<f32>,
    _pad: vec2<f32>,
};
@group(0) @binding(0) var<uniform> G: Globals;

struct VSOut {
    @builtin(position) pos: vec4<f32>,
    @location(0) color: vec4<f32>,
    @location(1) xywh: vec4<f32>,
    @location(2) radii: vec4<f32>,
    @location(3) stroke_px: f32,
    @location(4) pos_ndc: vec2<f32>,
    @location(5) fwd_mat: vec4<f32>,
};

@vertex
fn vs_main(
    @location(0) xywh: vec4<f32>,
    @location(1) radii: vec4<f32>,
    @location(2) stroke_px: f32,
    @location(3) color: vec4<f32>,
    @location(4) fwd_mat: vec4<f32>,
    @builtin(vertex_index) v: u32
) -> VSOut {
    var positions = array<vec2<f32>, 6>(
        vec2(0.0, 0.0), vec2(1.0, 0.0), vec2(1.0, 1.0),
        vec2(0.0, 0.0), vec2(1.0, 1.0), vec2(0.0, 1.0)
    );
    let p = positions[v];
    let half = 0.5 * xywh.zw;
    let corner = (p * 2.0 - 1.0) * half;
    let rotated = vec2(
        fwd_mat.x * corner.x + fwd_mat.y * corner.y,
        fwd_mat.z * corner.x + fwd_mat.w * corner.y
    );
    let pos_ndc = xywh.xy + rotated;

    var out: VSOut;
    out.pos = vec4(pos_ndc, 0.0, 1.0);
    out.xywh = xywh;
    out.radii = radii;
    out.stroke_px = stroke_px;
    out.color = color;
    out.pos_ndc = pos_ndc;
    out.fwd_mat = fwd_mat;
    return out;
}

fn corner_radius(p: vec2<f32>, r: vec4<f32>) -> f32 {
    return select(
        select(r[3], r[2], p.x >= 0.0),
        select(r[0], r[1], p.x >= 0.0),
        p.y >= 0.0
    );
}

fn sdf_round_box_px(p_px: vec2<f32>, half_px: vec2<f32>, r: vec4<f32>) -> f32 {
    let ri = corner_radius(p_px, r);
    let ri_clamped = max(ri, 0.0);
    let q = abs(p_px) - (half_px - vec2<f32>(ri_clamped, ri_clamped));
    let outside = max(q, vec2<f32>(0.0));
    let inside = min(max(q.x, q.y), 0.0);
    return length(outside) + inside - ri_clamped;
}

@fragment
fn fs_main(in: VSOut) -> @location(0) vec4<f32> {
    let center_ndc = in.xywh.xy;
    let p_px = (in.pos_ndc - center_ndc) * G.ndc_to_px;
    let half_px = 0.5 * in.xywh.zw * G.ndc_to_px;

    let det = max(
        in.fwd_mat.x * in.fwd_mat.w - in.fwd_mat.y * in.fwd_mat.z,
        1e-6,
    );
    let unrotated_px = vec2(
        (in.fwd_mat.w * p_px.x - in.fwd_mat.y * p_px.y) / det,
        (-in.fwd_mat.z * p_px.x + in.fwd_mat.x * p_px.y) / det,
    );

    let stroke = max(in.stroke_px, 0.0);
    let radii_clamped = max(in.radii, vec4<f32>(0.0));

    let d_outer = sdf_round_box_px(unrotated_px, half_px, radii_clamped);

    let half_inner = max(half_px - vec2<f32>(stroke, stroke), vec2<f32>(0.0));
    let r_inner = max(radii_clamped - vec4<f32>(stroke), vec4<f32>(0.0));
    let d_inner = sdf_round_box_px(unrotated_px, half_inner, r_inner);

    let w0 = max(fwidth(d_outer), 1e-4);
    let w1 = max(fwidth(d_inner), 1e-4);

    let cov_outer = 1.0 - smoothstep(-w0, w0, d_outer);
    let cov_inner = 1.0 - smoothstep(-w1, w1, d_inner);

    let ring = max(cov_outer - cov_inner, 0.0);

    let a = in.color.a * ring;
    return vec4(in.color.rgb * a, a);
}