rempl 0.1.0

A simple library for creating html components directly in your source
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87

{
  description = "Flake for rempl";

  inputs = {
    flake-parts.url = "github:hercules-ci/flake-parts";
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
    devshell.url = "github:numtide/devshell";
    devshell-helpers.url = "sourcehut:~yuiyukihira/devshell";
    rust-overlay = {
      url = "github:oxalica/rust-overlay";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    crane = {
      url = "github:ipetkov/crane";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    advisory-db = {
      url = "github:rustsec/advisory-db";
      flake = false;
    };
  };

  outputs = inputs@{ flake-parts, ... }:
    flake-parts.lib.mkFlake { inherit inputs; } {
      imports = [ inputs.devshell.flakeModule ];
      systems =
        [ "x86_64-linux" "aarch64-linux" "aarch64-darwin" "x86_64-dawin" ];
      perSystem = { config, self', inputs', pkgs, system, ... }:
        let
          craneLib = (inputs.crane.mkLib pkgs).overrideToolchain
            (p: p.rust-bin.stable.latest.default);
          src = craneLib.cleanCargoSource ./.;

          commonArgs = {
            inherit src;
            strictDeps = true;

            buildInputs = [ ]
              ++ pkgs.lib.optionals pkgs.stdenv.isDarwin [ pkgs.libiconv ];
          };

          cargoArtifacts = craneLib.buildDepsOnly commonArgs;

          rempl =
            craneLib.buildPackage (commonArgs // { inherit cargoArtifacts; });
        in {
          _module.args.pkgs = import inputs.nixpkgs {
            inherit system;
            overlays = [ inputs.rust-overlay.overlays.default ];
          };

          checks = {
            inherit rempl;
            rempl-clippy = craneLib.cargoClippy (commonArgs // {
              inherit cargoArtifacts;
              cargoClippyExtraArgs = "--all-targets -- --deny warnings";
            });
            rempl-docs =
              craneLib.cargoDoc (commonArgs // { inherit cargoArtifacts; });

            rempl-fmt = craneLib.cargoFmt { inherit src; };

            rempl-audit = craneLib.cargoAudit {
              inherit src;
              inherit (inputs) advisory-db;
            };

            rempl-deny = craneLib.cargoDeny { inherit src; };

            rempl-nextest = craneLib.cargoNextest (commonArgs // {
              inherit cargoArtifacts;
              partitions = 1;
              partitionType = "count";
            });
          };

          devshells.default = {
            imports =
              [ inputs.devshell-helpers.devshellProfiles.language.rust ];

            language.rust.packageSet = pkgs.rust-bin.stable.latest.default;

            packages = with pkgs; [ git-cliff cargo-release ];
          };
        };
    };
}