refined 0.3.1

Simple refinement types; parse, don't validate!
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154

{
  description = "Simple refinement types for Rust with Serde support";

  inputs = {
    nixpkgs.url = "nixpkgs/nixos-24.11";
    fenix = {
      url = "github:nix-community/fenix/monthly";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    devenv = {
      url = "github:jkaye2012/devenv";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    crane.url = "github:ipetkov/crane";
  };

  outputs =
    {
      self,
      fenix,
      nixpkgs,
      devenv,
      crane,
    }:
    devenv.lib.forAllSystems nixpkgs (
      system:
      let
        pkgs = nixpkgs.legacyPackages.${system};
        fenix' = fenix.packages.${system};
        crane' = (crane.mkLib pkgs).overrideToolchain fenix'.complete.toolchain;
        crane-stable = (crane.mkLib pkgs).overrideToolchain fenix'.stable.minimalToolchain;
        manifest = (pkgs.lib.importTOML ./Cargo.toml).package;

        src = crane'.cleanCargoSource ./.;

        buildExample =
          {
            src,
            subdir,
            args ? { },
          }:
          crane'.buildPackage {
            inherit src;
            cargoLock = ./${subdir}/Cargo.lock;
            cargoToml = ./${subdir}/Cargo.toml;

            postUnpack = ''
              cd $sourceRoot/${subdir}
              sourceRoot="."
            '';
          }
          // args;

        testFeature =
          feature:
          crane'.buildPackage {
            inherit src;
            cargoTestExtraArgs = "--no-default-features --all-targets --features ${feature}";
          };

        refined = crane'.buildPackage {
          inherit src;
          cargoTestExtraArgs = "--all-features";
        };

        refined-stable = crane-stable.buildPackage {
          inherit src;
          cargoTestExtraArgs = "--lib";
        };

        refined-no-std = crane'.buildPackage {
          inherit src;
          cargoTestExtraArgs = "--no-default-features --all-targets";
        };

        refined-doc = crane'.cargoDoc {
          inherit src;
          cargoArtifacts = refined;
          cargoDocExtraArgs = "--all-features";
        };

        refined-example-quickstart = buildExample {
          inherit src;
          subdir = "examples/quickstart";
          args = {
            cargoArtifacts = refined;
          };
        };

        refined-example-optimized = buildExample {
          inherit src;
          subdir = "examples/optimized";
          args = {
            cargoArtifacts = refined;
          };
        };

        refined-example-axum = buildExample {
          inherit src;
          subdir = "examples/axum";
          args = {
            cargoArtifacts = refined;
          };
        };
      in
      {
        devShells.${system}.default = pkgs.mkShell {
          inherit (manifest) name;

          inputsFrom = [ devenv.devShells.${system}.default ];

          packages = with pkgs; [
            cargo-show-asm
            fenix'.complete.toolchain
            linuxPackages_latest.perf
            lldb
          ];

          RUSTDOCFLAGS = "--cfg docsrs";
        };

        checks.${system} = {
          inherit
            refined
            refined-stable
            refined-no-std
            refined-doc
            refined-example-axum
            refined-example-quickstart
            refined-example-optimized
            ;
          refined-test-serde = testFeature "serde";
          refined-test-alloc = testFeature "alloc";
          refined-test-std = testFeature "std";
          refined-test-optimized = testFeature "optimized";
          refined-test-implication = testFeature "implication";
          refined-test-arithmetic = testFeature "arithmetic";
          refined-test-regex = testFeature "regex";
          refined-test-full = testFeature "full";
        };

        packages.${system} = rec {
          inherit
            refined
            refined-doc
            refined-example-axum
            refined-example-quickstart
            refined-example-optimized
            ;
          default = refined;
        };
      }
    );
}