rattice 0.6.1

A media viewer for web browsers.
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141

{
  description = "A media viewer for web browsers.";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";

    flake-parts = {
      url = "github:hercules-ci/flake-parts";
      inputs.nixpkgs-lib.follows = "nixpkgs";
    };

    rust-overlay = {
      url = "github:oxalica/rust-overlay";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    nix-appimage = {
      url = "github:ralismark/nix-appimage";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  outputs =
    inputs@{ self, ... }:
    inputs.flake-parts.lib.mkFlake { inherit inputs; } rec {
      systems = [
        "x86_64-linux"
        "armv7l-linux"
        "aarch64-linux"
        "x86_64-darwin"
        "aarch64-darwin"
      ];
      perSystem =
        { system, lib, ... }:
        let
          name = "rattice";
          pname = name;
          crossSystems = systems ++ [
            "mipsel-linux-gnu"
          ];

          overlays = [ (import inputs.rust-overlay) ];
          pkgs = import inputs.nixpkgs { inherit system overlays; };

          pkgsCrossFor =
            crossSystem:
            import inputs.nixpkgs {
              inherit system overlays crossSystem;
            };

          rustPlatformFor =
            pkgs:
            if pkgs.system == "x86_64-linux" then
              pkgs.makeRustPlatform {
                cargo = pkgs.rust-bin.stable.latest.minimal;
                rustc = pkgs.rust-bin.stable.latest.minimal;
              }
            else
              pkgs.rustPlatform;

          buildFor =
            pkgs:
            (rustPlatformFor pkgs).buildRustPackage {
              inherit name pname;
              src = ./.;
              version = self.shortRev or self.dirtyShortRev or "dev";
              meta.mainProgram = name;

              cargoLock = {
                lockFile = ./Cargo.lock;
                allowBuiltinFetchGit = true;
              };
            };

          buildDockerFor =
            pkgs:
            pkgs.dockerTools.buildLayeredImage {
              inherit name;
              tag = "latest";
              contents = [ (buildFor pkgs) ];
              config = {
                WorkingDir = "/workdir";
                Entrypoint = "/bin/${name}";
              };
            };

          buildAppImageFor =
            package:
            inputs.nix-appimage.lib.${system}.mkAppImage {
              program = "${package}/bin/${name}";
            };
        in
        {
          packages = rec {
            default = bin;
            bin = buildFor pkgs;
            static = buildFor pkgs.pkgsStatic;
            docker = buildDockerFor pkgs;
            appimage = buildAppImageFor bin;
          };

          legacyPackages =
            # Cross build
            (lib.listToAttrs (
              map (
                crossSystem: lib.nameValuePair "bin-${crossSystem}" (buildFor (pkgsCrossFor crossSystem))
              ) crossSystems
            ))

            # Static cross build
            // (lib.listToAttrs (
              map (
                crossSystem:
                lib.nameValuePair "static-${crossSystem}" (buildFor (pkgsCrossFor crossSystem).pkgsStatic)
              ) crossSystems
            ))

            # Docker cross build
            // (lib.listToAttrs (
              map (
                crossSystem: lib.nameValuePair "docker-${crossSystem}" (buildDockerFor (pkgsCrossFor crossSystem))
              ) crossSystems
            ));

          devShells.default = pkgs.mkShell {
            buildInputs = with pkgs.rust-bin; [
              (stable.latest.minimal.override {
                extensions = [
                  "clippy"
                  "rust-src"
                ];
              })
              nightly.latest.rustfmt
              nightly.latest.rust-analyzer
            ];

            RUST_BACKTRACE = 1;
          };
        };
    };
}