rafx-plugins 0.0.16

Rendering framework built on an extensible asset pipeline
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72

#version 450
#extension GL_ARB_separate_shader_objects : enable
#include "../post_shared/tonemapping.glsl"

// @[export]
layout (set = 0, binding = 0) uniform texture2D in_color;

// @[export]
layout (set = 0, binding = 1) uniform texture2D in_blur;

// @[immutable_samplers([
//         (
//             mag_filter: Nearest,
//             min_filter: Nearest,
//             mip_map_mode: Linear,
//             address_mode_u: ClampToEdge,
//             address_mode_v: ClampToEdge,
//             address_mode_w: ClampToEdge,
//         )
// ])]
layout (set = 0, binding = 2) uniform sampler smp;

// Should be kept in sync with the constants in OutputColorSpace
const int OUTPUT_COLOR_SPACE_SRGB = 0;
const int OUTPUT_COLOR_SPACE_P3 = 1;

// @[export]
// @[internal_buffer]
layout (set = 0, binding = 3) uniform Config {
    int tonemapper_type;
    int output_color_space;
    float max_color_component_value;
} config;

layout (location = 0) in vec2 inUV;

layout (location = 0) out vec4 out_sdr;

// Source: kolor
const mat3 sRGB_to_P3 = mat3(
    0.8224886, 0.033200048, 0.017089065,
    0.17751142, 0.9668, 0.072411515,
    0.00000000000000005551115, -0.000000000000000017347235, 0.9104994
);

void main()
{
    // Combine SDR + blurred HDR
    vec4 rgb = texture(sampler2D(in_color, smp), inUV) + texture(sampler2D(in_blur, smp), inUV);
    vec3 color = rgb.rgb;

    if (color == vec3(0)) {
        out_sdr = vec4(color, 1);
        return;
    }

    vec3 color_srgb_linear = tonemap_basic(
        color,
        config.tonemapper_type
    );

    switch (config.output_color_space)
    {
        case OUTPUT_COLOR_SPACE_SRGB:
            out_sdr = vec4(color_srgb_linear, 1.0);
            break;
        case OUTPUT_COLOR_SPACE_P3:
            vec3 color_linear_p3 = sRGB_to_P3 * color_srgb_linear;
            out_sdr = vec4(color_linear_p3, 1.0);
            break;
    }
}