qrab 0.1.1

A readable quantum-circuit compiler for TikZ and Typst
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59

default: check

fmt:
    cargo fmt --all

fmt-check:
    cargo fmt --all -- --check

lint:
    cargo clippy --workspace --all-targets --all-features -- -D warnings

test:
    cargo nextest run --workspace --all-targets
    cargo test --doc

test-artifacts:
    cargo nextest run --test artifacts --run-ignored ignored-only

check: fmt-check lint test

ci: check test-artifacts

package:
    cargo package --locked

release-check: ci
    cargo build --release --locked
    cargo package --locked

gen-assets:
    cargo run --locked --quiet -p xtask

# Regenerate the manual's diagrams and typeset it.
manual: gen-assets
    typst compile --root . docs/manual.typ docs/manual.pdf

# Build the WebAssembly module the playground loads.
playground:
    wasm-pack build playground --target web --out-dir www/pkg --no-typescript

# Serve the playground at http://localhost:8080 after building it.
playground-serve: playground
    python3 -m http.server 8080 --directory playground/www

install-local:
    cargo install --path . --locked

# Compile one example through every backend, writing to target/ so nothing
# generated lands next to the sources.
example:
    mkdir -p target/example
    cargo run -- compile examples/teleportation.qrab -t latex -o target/example/teleportation.tex
    cargo run -- compile examples/teleportation.qrab -t typst -o target/example/teleportation.typ
    cargo run -- compile examples/teleportation.qrab -t svg -o target/example/teleportation.svg
    tectonic target/example/teleportation.tex --outdir target/example
    typst compile target/example/teleportation.typ target/example/teleportation-typst.pdf

install-hooks:
    pre-commit install --install-hooks