putter 0.0.1

A tool to put files in the right place
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99

{
  description = "Home Manager file management tool";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";
    flake-utils.url = "github:numtide/flake-utils";
    crane.url = "github:ipetkov/crane?ref=v0.20.3";
    pre-commit-hooks = {
      url = "github:cachix/pre-commit-hooks.nix";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  outputs =
    {
      self,
      nixpkgs,
      flake-utils,
      crane,
      pre-commit-hooks,
    }:
    let
      systems = [
        "aarch64-linux"
        "aarch64-darwin"
        "x86_64-darwin"
        "x86_64-linux"
      ];
    in
    flake-utils.lib.eachSystem systems (
      system:
      let
        pkgs = nixpkgs.legacyPackages.${system};
        craneLib = crane.mkLib pkgs;

        src = craneLib.cleanCargoSource ./.;

        commonArgs = {
          inherit src;
          meta = with pkgs.lib; {
            description = "Home Manager file management tool";
            homepage = "https://sr.ht/~rycee/putter/";
            license = licenses.gpl3Plus;
            mainProgram = "putter";
            platforms = platforms.unix;
          };
        };

        cargoArtifacts = craneLib.buildDepsOnly commonArgs;

        crateClippy = craneLib.cargoClippy (commonArgs // { inherit cargoArtifacts; });

        crateCoverage = craneLib.cargoTarpaulin (
          commonArgs
          // {
            inherit cargoArtifacts;
            cargoTarpaulinExtraArgs = "--skip-clean --verbose --out html --output-dir $out";
          }
        );

        crate = craneLib.buildPackage (commonArgs // { inherit cargoArtifacts; });

        pre-commit-check = pre-commit-hooks.lib.${system}.run {
          inherit src;
          hooks = {
            convco.enable = true;
            nixfmt-rfc-style.enable = true;
            rustfmt.enable = true;
          };
        };
      in
      {
        packages = {
          default = crate;
          inherit cargoArtifacts crateCoverage;
        };

        apps.default = flake-utils.lib.mkApp { drv = crate; };

        checks = {
          inherit
            crate
            crateClippy
            crateCoverage
            pre-commit-check
            ;
        };

        devShells.default = craneLib.devShell {
          checks = self.checks.${system};
          packages = with pkgs; [
            cargo-audit
            cargo-outdated
          ];
          shellHook = pre-commit-check.shellHook;
        };
      }
    );
}