putter 0.1.0

A tool to put files in the right place
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120

{
  description = "Home Manager file management tool";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";
    crane.url = "github:ipetkov/crane?ref=v0.21.3";
    pre-commit-hooks = {
      url = "github:cachix/pre-commit-hooks.nix";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  outputs =
    {
      self,
      nixpkgs,
      crane,
      pre-commit-hooks,
    }:
    let
      systems = [
        "aarch64-linux"
        "aarch64-darwin"
        "x86_64-darwin"
        "x86_64-linux"
      ];

      forAllSystems =
        f:
        nixpkgs.lib.genAttrs systems (
          system:
          f rec {
            inherit system;
            pkgs = nixpkgs.legacyPackages.${system};
            craneLib = crane.mkLib pkgs;

            src = craneLib.cleanCargoSource ./.;

            commonArgs = {
              inherit src;
              meta = with pkgs.lib; {
                description = "Home Manager file management tool";
                homepage = "https://sr.ht/~rycee/putter/";
                license = licenses.eupl12; # Actually EUPL-1.2+
                mainProgram = "putter";
                platforms = platforms.unix;
              };
            };

            cargoArtifacts = craneLib.buildDepsOnly commonArgs;

            crateCoverage = craneLib.cargoTarpaulin (
              commonArgs
              // {
                inherit cargoArtifacts;
                cargoTarpaulinExtraArgs = "--skip-clean --verbose --out html --output-dir $out";
              }
            );

            crate = craneLib.buildPackage (commonArgs // { inherit cargoArtifacts; });

            pre-commit-check = pre-commit-hooks.lib.${system}.run {
              inherit src;
              hooks = {
                convco.enable = true;
                nixfmt.enable = true;
                rustfmt.enable = true;
              };
            };
          }
        );
    in
    {
      packages = forAllSystems (p: {
        default = p.crate;
        inherit (p) cargoArtifacts crateCoverage;
      });

      checks = forAllSystems (p: {
        inherit (p) crate pre-commit-check;

        clippy =
          with p;
          craneLib.cargoClippy (
            commonArgs
            // {
              inherit cargoArtifacts;
              cargoClippyExtraArgs = "--all-targets -- --deny warnings";
            }
          );

        deny = with p; craneLib.cargoDeny commonArgs;
      });

      devShells = forAllSystems (p: {
        default = p.craneLib.devShell {
          checks = self.checks.${p.system};
          packages = with p.pkgs; [
            cargo-audit
            cargo-deny
            cargo-outdated
            cargo-semver-checks
            cargo-tarpaulin
            git-cliff

            (treefmt.withConfig {
              runtimeInputs = [
                deadnix
                nixfmt
                rustfmt
                taplo
              ];
              settings = pkgs.lib.importTOML ./treefmt.toml;
            })
          ];
          shellHook = p.pre-commit-check.shellHook;
        };
      });
    };
}