pump-rust-client 0.1.3

Rust SDK for the pump and pump_amm Solana programs: instruction builders, quoting, PDA helpers, and optional RPC client features.
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34

tests := "buy_sell_instructions trade_tx_and_quotes async_client_fetchers create_v2_devnet_clone"

default:
    @just --list

build:
    cargo build --features local-validator

clone-accounts:
    cargo run --features local-validator --bin clone_devnet_accounts

local-validator: clone-accounts
    cargo run --features local-validator --bin local-validator

test:
    #!/usr/bin/env bash
    set -euo pipefail
    for t in {{tests}}; do
        echo "=== $t ==="
        cargo test --features local-validator --test "$t" -- --ignored --nocapture
    done

test-one name:
    cargo test --features local-validator --test {{name}} -- --ignored --nocapture

build-and-test: build
    #!/usr/bin/env bash
    set -euo pipefail
    just clone-accounts
    cargo run --features local-validator --bin local-validator &
    validator_pid=$!
    trap "kill $validator_pid 2>/dev/null || true" EXIT
    sleep 10
    just test