psm 0.1.31

Portable Stack Manipulation: stack manipulation and introspection routines
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61

PUBLIC rust_psm_stack_direction
PUBLIC rust_psm_stack_pointer
PUBLIC rust_psm_replace_stack
PUBLIC rust_psm_on_stack

_TEXT SEGMENT

; extern "sysv64" fn() -> u8 (%al)
rust_psm_stack_direction PROC
    mov al, 2
    ret
rust_psm_stack_direction ENDP

; extern "sysv64" fn() -> *mut u8 (%rax)
rust_psm_stack_pointer PROC
    lea rax, [rsp + 8]
    ret
rust_psm_stack_pointer ENDP

; extern "sysv64" fn(%rdi: usize, %rsi: extern "sysv64" fn(usize), %rdx: *mut u8, %rcx: *mut u8)
rust_psm_replace_stack PROC
    mov gs:[08h], rdx
    mov gs:[10h], rcx
    lea rsp, [rdx - 8]
    jmp rsi
rust_psm_replace_stack ENDP

; extern "sysv64" fn(%rdi: usize, %rsi: usize,
;                    %rdx: extern "sysv64" fn(usize, usize), %rcx: *mut u8, %r8: *mut u8)
;
; NB: on Windows for SEH to work at all, the pointers in TIB, thread information block, need to be
; fixed up. Otherwise, it seems that exception mechanism on Windows will not bother looking for
; exception handlers at *all* if they happen to fall outside the are specified in TIB.
;
; This necessitates an API difference from the usual 4-argument signature used elsewhere.
;
; FIXME: this needs a catch-all exception handler that aborts in case somebody unwinds into here.
rust_psm_on_stack PROC FRAME
    push rbp
    .pushreg rbp
    mov rbp, rsp
    .setframe rbp, 0
    .endprolog

    push gs:[08h]
    mov gs:[08h], rcx
    push gs:[10h]
    mov gs:[10h], r8
    mov rsp, rcx
    call rdx
    lea rsp, [rbp - 010h]
    pop gs:[10h]
    pop gs:[08h]

    pop rbp
    ret
rust_psm_on_stack ENDP

_TEXT ENDS

END