protoc-gen-rust-grpc 0.9.0

Protobuf plugin to generate gRPC-Rust service bindings
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141

cmake_minimum_required(VERSION 3.14)
project(protoc-gen-rust-grpc LANGUAGES CXX)

# Parse version from Cargo.toml unless already set (e.g. from CI or environment)
if(NOT RUST_GRPC_VERSION)
    if(DEFINED ENV{RUST_GRPC_VERSION})
        set(RUST_GRPC_VERSION "$ENV{RUST_GRPC_VERSION}")
    else()
        file(READ "${CMAKE_CURRENT_SOURCE_DIR}/../../Cargo.toml" CARGO_TOML_CONTENT)
        string(REGEX MATCH "\nversion[ \t]*=[ \t]*\"([^\"]+)\"" _ "${CARGO_TOML_CONTENT}")
        set(RUST_GRPC_VERSION ${CMAKE_MATCH_1})
    endif()
endif()
add_compile_definitions(RUST_GRPC_VERSION="${RUST_GRPC_VERSION}")

set(CMAKE_CXX_STANDARD 17)
set(CMAKE_CXX_STANDARD_REQUIRED ON)
set(CMAKE_EXPORT_COMPILE_COMMANDS ON)

if(MINGW)
    add_compile_options("-Wa,-mbig-obj")
    add_compile_definitions(_WIN32_WINNT=0x0601)
elseif(MSVC)
    add_compile_options("/bigobj")
endif()

# Options
set(PROTOBUF_VERSION "34.0" CACHE STRING "Version of protobuf to download")
option(BUILD_SHARED_LIBS "Build shared libraries" OFF)
option(BUILD_PROTOC "Build protoc executable" ON)
option(BUILD_PLUGIN "Build protoc-gen-rust-grpc plugin" ON)

# Add cmake directory to module path
list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/cmake")

# Include modules
include(FetchContent)
include(FetchProtobuf)

# Download and configure abseil
# Abseil version that's compatible with protobuf
set(ABSEIL_VERSION "20240722.0")
set(ABSEIL_URL "https://github.com/abseil/abseil-cpp/archive/refs/tags/${ABSEIL_VERSION}.tar.gz")

message(STATUS "Downloading abseil-cpp ${ABSEIL_VERSION}")

FetchContent_Declare(
    absl
    URL ${ABSEIL_URL}
    URL_HASH SHA256=f50e5ac311a81382da7fa75b97310e4b9006474f9560ac46f54a9967f07d4ae3
    DOWNLOAD_EXTRACT_TIMESTAMP TRUE
)

# Set abseil build options
set(ABSL_PROPAGATE_CXX_STD ON CACHE BOOL "" FORCE)
set(ABSL_BUILD_TESTING OFF CACHE BOOL "" FORCE)
set(BUILD_TESTING OFF CACHE BOOL "" FORCE)

# Force using the fetched abseil instead of system abseil
set(CMAKE_FIND_PACKAGE_PREFER_CONFIG TRUE)
set(absl_DIR "${CMAKE_CURRENT_BINARY_DIR}/_deps/absl-build" CACHE PATH "" FORCE)
# Prevent finding system libraries
set(CMAKE_PREFIX_PATH "" CACHE STRING "" FORCE)

FetchContent_MakeAvailable(absl)

# Prevent protobuf from using a local version of abseil
set(protobuf_ABSL_PROVIDER "package" CACHE STRING "Use external Abseil" FORCE)

# Download and configure protobuf
fetch_protobuf(${PROTOBUF_VERSION})

# Add the protoc-gen-rust-grpc executable and installation rules
if(BUILD_PLUGIN)
    add_executable(protoc-gen-rust-grpc
        src/grpc_rust_plugin.cc
        src/grpc_rust_generator.cc
        src/grpc_rust_generator.h
    )

    # Link against protobuf and abseil
    target_link_libraries(protoc-gen-rust-grpc
        PRIVATE
            protobuf::libprotoc
            protobuf::libprotobuf
            absl::flat_hash_map
            absl::strings
            absl::string_view
    )

    # Include directories
    target_include_directories(protoc-gen-rust-grpc
        PRIVATE
            ${protobuf_SOURCE_DIR}/src
            ${CMAKE_CURRENT_SOURCE_DIR}
    )

    # Set output directory
    set_target_properties(protoc-gen-rust-grpc
        PROPERTIES
            RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin
    )

    install(TARGETS protoc-gen-rust-grpc
        RUNTIME DESTINATION bin
    )
endif()

if(BUILD_PROTOC)
    # Add protoc executable as a custom target that copies the built protoc and installation rules
    # We explicitly name it "protoc" without version suffix
    if(WIN32)
        set(PROTOC_OUTPUT_NAME "protoc.exe")
    else()
        set(PROTOC_OUTPUT_NAME "protoc")
    endif()

    add_custom_target(copy-protoc ALL
        COMMAND ${CMAKE_COMMAND} -E copy_if_different
            $<TARGET_FILE:protoc>
            ${CMAKE_BINARY_DIR}/bin/${PROTOC_OUTPUT_NAME}
        DEPENDS protoc
        COMMENT "Copying protoc to output directory"
    )

    install(PROGRAMS ${CMAKE_BINARY_DIR}/bin/${PROTOC_OUTPUT_NAME}
        DESTINATION bin
    )
endif()

# Print summary
message(STATUS "")
message(STATUS "protoc-gen-rust-grpc configuration summary:")
message(STATUS "  Crate Version: ${RUST_GRPC_VERSION}")
message(STATUS "  Protobuf version: ${PROTOBUF_VERSION}")
message(STATUS "  Abseil version: ${ABSEIL_VERSION}")
message(STATUS "  Build type: ${CMAKE_BUILD_TYPE}")
message(STATUS "  C++ standard: ${CMAKE_CXX_STANDARD}")
message(STATUS "  Output directory: ${CMAKE_BINARY_DIR}/bin")
message(STATUS "  Build protoc: ${BUILD_PROTOC}")
message(STATUS "  Build plugin: ${BUILD_PLUGIN}")