proc-macro-error3 3.0.2

Almost drop-in replacement to panics in proc-macros
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128

# spell-checker: ignore nofile nocapture

prettier_bin := ```
    if command -V prettier 2>&1 | grep -q 'not found'; then
        echo -n npx prettier
    else
        echo -n prettier
    fi
    ```
cspell_bin := ```
    if command -V cspell 2>&1 | grep -q 'not found'; then
        echo -n npx cspell
    else
        echo -n cspell
    fi
    ```
msrv := '1.61.0'

# Check and fix format of rust files (Uses: 'cargo +nightly')
[group('formatting')]
fmt:
    cargo +nightly fmt --all

# Check and fix format of toml files (Uses: 'taplo')
[group('formatting')]
fmt-toml:
    taplo fmt

# Check and fix format of json and yaml files (Uses: 'prettier' or 'npx prettier')
[group('formatting')]
fmt-prettier:
    {{ prettier_bin }} --write .

# Run all fmt rules (Depends on: fmt, fmt-toml, fmt-prettier)
[group('formatting')]
fmt-all: fmt fmt-toml fmt-prettier

# Check format of rust files (Uses: 'cargo +nightly')
[group('formatting')]
check-fmt:
    cargo +nightly fmt --all --check

# Check format of toml files with `taplo` (Uses: 'taplo')
[group('formatting')]
check-fmt-toml:
    taplo fmt --check --verbose

# Check format of json and yaml files (Uses: 'prettier' or 'npx prettier')
[group('formatting')]
check-fmt-prettier:
    {{ prettier_bin }} --check --log-level warn .

# Check spelling with cspell (Uses: 'cspell' or 'npx cspell')
[group('formatting')]
check-spelling:
    {{ cspell_bin }} lint .

# Run all format checkers (Depends on: check-fmt, check-fmt-toml, check-fmt-prettier, check-spelling)
[group('formatting')]
check-fmt-all: check-fmt check-fmt-toml check-fmt-prettier check-spelling

# Run clippy (Uses: 'cargo +stable')
[group('lint')]
lint:
    cargo +stable clippy --features syn-error,__ui_tests --all-targets -- -D warnings
    cargo +nightly clippy --features nightly,syn-error,__ui_tests --all-targets -- -D warnings

# Check minimal supported Rust version (Uses: 'cargo +{{ msrv }}')
[group('lint')]
lint-msrv:
    cargo +{{ msrv }} check --all

# Run cargo deny check (Uses: 'cargo-deny')
[group('dependencies')]
deny +args='all':
    cargo deny check {{ args }}

# Generate and update Cargo.lock with cargo resolver v3 fallback (Uses: 'cargo +stable')
[group('dependencies')]
update-dependencies:
    CARGO_RESOLVER_INCOMPATIBLE_RUST_VERSIONS=fallback cargo +stable update

# Check minimal version requirements of dependencies (Uses: 'cargo-minimal-versions')
[group('dependencies')]
minimal-versions:
    cargo minimal-versions check --workspace --all-targets --ignore-private --direct

# Build the workspace (Uses: 'cargo')
[group('build')]
build:
    cargo build --all

# Build the documentation (Uses: 'cargo')
[group('build')]
build-docs:
    DOCS_RS=1 cargo doc --no-deps --workspace --document-private-items
    DOCS_RS=1 cargo +nightly doc --features nightly --no-deps --workspace --document-private-items

# Run all tests (Uses: 'cargo')
[group('test')]
test:
    cargo test --all

# Run all tests with nightly features (Uses: 'cargo +nightly')
[group('test')]
test-nightly:
    cargo +nightly test --all --features nightly

# Run all doc tests (Uses: 'cargo')
[group('test')]
test-doc:
    DOCS_RS=1 cargo test --doc
    DOCS_RS=1 cargo +nightly test --features nightly --doc

# Run the UI tests (Uses: 'cargo +stable')
[group('test')]
test-ui:
    cargo +stable test --features __ui_tests ui

# Run the UI tests and overwrite the error message fixtures (Uses: 'cargo +stable')
[group('test')]
test-ui-overwrite:
    TRYBUILD=overwrite cargo +stable test --features __ui_tests ui

# Test all packages (Uses: 'cargo')
[group('test')]
test-all: test-ui test-nightly test-doc
    cargo test --all