plua 0.1.0

Lua preprocessor inspired by Nelua
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78

Program = _{ SOI ~ Content* ~ EOI }

Content = _{ Meta | Lua+ | EOL }

Lua = { LuaChar+ }

LuaChar = _{ !Reserved ~ ANY }

Reserved = { MetaReserved | MetaCodeBlockPrefix | MetaCodeBlockSuffix }

MetaReserved = {
    MetaCodeMultiPrefix
  | MetaCodeMultiSuffix
  | MetaIncludePrefix
  | MetaCodeSinglePrefix
  | MetaValueInterpolatePrefix
  | MetaValueInterpolateSuffix
  | MetaExpressionInterpolatePrefix
  | MetaExpressionInterpolateSuffix
}

EOL = _{ "\n" | "\r\n" }

End = { EOL | &EOI }

Character = _{ !(EOL | Reserved) ~ ANY }

Quote = _{ "\"" }

Meta = _{
    &"#" ~ (MetaInclude | MetaCode | MetaValueInterpolate | MetaExpressionInterpolate)
}

MetaInclude = _{ MetaIncludePrefix ~ Quote ~ MetaIncludeFile ~ Quote ~ End }

MetaIncludePrefix = _{ "##!include " }

MetaIncludeFile = { (!Quote ~ Character)* }

MetaCode = _{ &"##" ~ (MetaCodeMulti | MetaCodeSingle) }

MetaCodeMulti = _{ MetaCodeMultiPrefix ~ MetaCodeMultiBody* ~ MetaCodeMultiSuffix }

MetaCodeMultiPrefix = _{ "##[[" }

MetaCodeMultiSuffix = _{ "]]" }

MetaCodeMultiBody = { MetaCodeBlock | LuaChar+ }

MetaCodeSingle = _{ MetaCodeSinglePrefix ~ MetaCodeSingleBody* ~ End }

MetaCodeSinglePrefix = _{ "##" }

MetaCodeSingleBody = { MetaCodeBlock | Character+ }

MetaCodeBlock = _{ MetaCodeBlockPrefix ~ (MetaCodeBlockBody | MetaValueInterpolate | MetaExpressionInterpolate)* ~ MetaCodeBlockSuffix }

MetaCodeBlockPrefix = _{ "#{" }

MetaCodeBlockSuffix = _{ "}#" }

MetaCodeBlockBody = { LuaChar+ }

MetaValueInterpolate = _{ MetaValueInterpolatePrefix ~ MetaValueInterpolateBody ~ MetaValueInterpolateSuffix }

MetaValueInterpolatePrefix = _{ "#[" }

MetaValueInterpolateSuffix = _{ "]#" }

MetaValueInterpolateBody = { LuaChar* }

MetaExpressionInterpolate = _{ MetaExpressionInterpolatePrefix ~ MetaExpressionInterpolateBody ~ MetaExpressionInterpolateSuffix }

MetaExpressionInterpolatePrefix = _{ "#|" }

MetaExpressionInterpolateSuffix = _{ "|#" }

MetaExpressionInterpolateBody = { LuaChar* }