planter-core 0.0.7

Domain logic for PlanTer, a project management application
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80

{
  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
    rust-overlay = {
      url = "github:oxalica/rust-overlay";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  outputs = { self, nixpkgs, rust-overlay }:
    let
      lib = nixpkgs.lib;
      systems = [
        "x86_64-linux"
        "aarch64-linux"
        "aarch64-darwin"
      ];
      pkgsFor = system: import nixpkgs {
        inherit system;
        overlays = [ (import rust-overlay) ];
      };
    in
    {
      devShells = lib.genAttrs systems (system:
        let
          pkgs = pkgsFor system;
          rustTarget = pkgs.stdenv.hostPlatform.rust.rustcTarget;

          toolchain = (pkgs.rust-bin.stable.latest.minimal.override {
            extensions = [ "clippy" "rustfmt" "rust-src" "llvm-tools" ];
          });
          ciToolchain = (pkgs.rust-bin.stable.latest.minimal.override {
            extensions = [ "clippy" "rustfmt" ];
          });
        in
        {
          default = pkgs.mkShell {
            packages = [
              toolchain
              pkgs.rust-analyzer
              pkgs.bacon
              pkgs.cargo-edit
              pkgs.cargo-deny
              pkgs.cargo-machete
              pkgs.cargo-llvm-cov
              pkgs.release-plz
            ];

            RUST_SRC_PATH = "${toolchain}/lib/rustlib/src/rust";

            shellHook = ''
              export LLVM_COV="${toolchain}/lib/rustlib/${rustTarget}/bin/llvm-cov"
              export LLVM_PROFDATA="${toolchain}/lib/rustlib/${rustTarget}/bin/llvm-profdata"
            '';
          };

          ci = pkgs.mkShell {
            packages = [
              ciToolchain
              pkgs.cargo-deny
              pkgs.cargo-machete
            ];
          };

          release = pkgs.mkShell {
            packages = [
              ciToolchain
              pkgs.release-plz
            ];
          };

          renovate = pkgs.mkShell {
            packages = [
              pkgs.renovate
              pkgs.git
            ];
          };
        });
    };
}