palate 0.3.9

File type detection combining tft and hyperpolyglot
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72

:- module expr.

:- interface.

:- import_module char, int, list.

:- type token
	--->	('+')
	;	('-')
	;	('*')
	;	('/')
	;	num(int)
	;	('(')
	;	(')')
	;	eof
	.

:- parse(exprn/1, token, eof, xx, in, out).

:- pred scan(list(char), list(token)).
:- mode scan(in, out) is det.

:- implementation.

:- import_module string, require.

:- rule exprn(int).
exprn(Num)	--->	exprn(A), [+], term(B), { Num = A + B }.
exprn(Num)	--->	exprn(A), [-], term(B), { Num = A - B }.
exprn(Num)	--->	term(Num).

:- rule term(int).
term(Num)	--->	term(A), [*], factor(B), { Num = A * B }.
term(Num)	--->	term(A), [/], factor(B), { Num = A // B }.
term(Num)	--->	factor(Num).

:- rule factor(int).
factor(Num)	--->	['('], exprn(Num), [')'].
factor(Num)	--->	[num(Num)].

scan(Chars, Toks) :-
	scan(Chars, [], Toks0),
	list__reverse(Toks0, Toks).

:- pred scan(list(char), list(token), list(token)).
:- mode scan(in, in, out) is det.

scan([], Toks, [eof|Toks]).
scan([C|Cs], Toks0, Toks) :-
	( char__is_whitespace(C) ->
		scan(Cs, Toks0, Toks)
	; char__is_digit(C) ->
		takewhile(char__is_digit, [C|Cs], Digits, Rest),
		string__from_char_list(Digits, NumStr),
		Num = string__det_to_int(NumStr),
		scan(Rest, [num(Num)|Toks0], Toks)
	; C = ('+') ->
		scan(Cs, ['+'|Toks0], Toks)
	; C = ('-') ->
		scan(Cs, ['-'|Toks0], Toks)
	; C = ('*') ->
		scan(Cs, ['*'|Toks0], Toks)
	; C = ('/') ->
		scan(Cs, ['/'|Toks0], Toks)
	; C = ('(') ->
		scan(Cs, ['('|Toks0], Toks)
	; C = (')') ->
		scan(Cs, [')'|Toks0], Toks)
	;
		error("expr: syntax error in input")
	).