p2sh 0.4.3

The p2sh Programming language interpreter
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62

#!/usr/bin/env p2sh

// Quick sort algorithm implementation
// Alternatively, the inbuilt 'sort()' method
// may also be used to sort an array of objects.

fn swap(a, i, j) {
    let t = a[i];
    a[i] = a[j];
    a[j] = t;
}

fn shuffle(a) {
    let i = 0;
    let n = len(a);
    while i < n {
        let r = rand() % n;
        swap(a, i, r);
        i = i + 1;
    }
}

fn partition(a, lo, hi) {
    let i = lo;
    let j = hi + 1;
    let v = a[lo];   //partitioning element
    while true {
        while a[i = i + 1] < v {
            if i == hi {
                break;
            }
        }
        while v < a[j = j - 1] {
            if j == lo {
                break;
            }
        }
        if i >= j {
            break;
        }
        swap(a, i, j);
    }
    swap(a, lo, j);
    return j;
}

fn sort_quick(a, lo, hi) {
    if hi <= lo {
        return;
    }
    let j = partition(a, lo, hi);
    sort_quick(a, lo, j - 1);
    sort_quick(a, j + 1, hi);
}

let a = [141, 1, 17, -7, -17, -27, 18, 541, 8, 7, 7];
puts(a);
shuffle(a);
// Builtin sort method
// sort(a, 0, len(a) - 1);
sort_quick(a, 0, len(a) - 1);
puts(a);