oxzy 0.3.0

Your oxidised fuzzer!
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121

{
  description = "Your oxidised fuzzer!";

  nixConfig = {
    extra-substituters = ["https://oxzy.cachix.org"];
    extra-trusted-public-keys = ["oxzy.cachix.org-1:ZDumoZJ9f1YTbu7n/mPVpcUkOroiUoKOuwNcbonsjb0="];
  };

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";

    crane = {
      url = "github:ipetkov/crane";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    flake-utils.url = "github:numtide/flake-utils";

    advisory-db = {
      url = "github:rustsec/advisory-db";
      flake = false;
    };
  };

  outputs = {
    self,
    nixpkgs,
    crane,
    flake-utils,
    advisory-db,
    ...
  }:
    flake-utils.lib.eachDefaultSystem (system: let
      pkgs = import nixpkgs {
        inherit system;
      };

      inherit (pkgs) lib;

      craneLib = crane.lib.${system};
      src = lib.cleanSourceWith {
        src = ./.;
        filter = path: type:
          (lib.hasSuffix "\.wasm" path)
          || (lib.hasInfix "/rsc/" path)
          || (craneLib.filterCargoSources path type);
      };

      commonArgs = {
        inherit src;
        buildInputs = with pkgs;
          [
            pkg-config
            glib
            atk
            gtk3
            librsvg
            gtk-layer-shell
          ]
          ++ lib.optionals pkgs.stdenv.isDarwin [];
      };

      cargoArtifacts = craneLib.buildDepsOnly commonArgs;

      oxzy = craneLib.buildPackage (commonArgs
        // {
          inherit cargoArtifacts;
        });
    in {
      formatter = pkgs.alejandra;

      checks = {
        inherit oxzy;

        oxzy-clippy = craneLib.cargoClippy (commonArgs
          // {
            inherit cargoArtifacts;
            cargoClippyExtraArgs = "--all-targets -- --deny warnings";
          });

        oxzy-doc = craneLib.cargoDoc (commonArgs
          // {
            inherit cargoArtifacts;
          });

        oxzy-fmt = craneLib.cargoFmt {
          inherit src;
        };

        oxzy-audit = craneLib.cargoAudit {
          inherit src advisory-db;
        };
      };

      packages.default = oxzy;

      apps.default = flake-utils.lib.mkApp {
        name = "oxzy";
        drv = oxzy;
      };

      devShells.default = pkgs.mkShell {
        inputsFrom = builtins.attrValues self.checks.${system};

        nativeBuildInputs = with pkgs; [
          alejandra # nix formatter
          rustfmt # rust formatter
          statix # lints and suggestions
          deadnix # clean up unused nix code
          rustc # rust compiler
          gcc # GNU Compiler Collection
          cargo # rust package manager
          clippy # opinionated rust formatter
          bacon

          rust-analyzer # rust analyzer
          lldb # software debugger
        ];
      };
    });
}