openpmix-src 0.1.0

Vendored build of OpenPMIx, developed for use by the Lamellar runtime.
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62

# -*- shell-script -*-
#
# Copyright (c) 2009-2015 Cisco Systems, Inc.  All rights reserved.
# Copyright (c) 2013      Los Alamos National Security, LLC.  All rights reserved.
# Copyright (c) 2013-2020 Intel, Inc.  All rights reserved.
# Copyright (c) 2021-2024 Nanook Consulting  All rights reserved.
# Copyright (c) 2022      Amazon.com, Inc. or its affiliates.
#                         All Rights reserved.
# $COPYRIGHT$
#
# Additional copyrights may follow
#
# $HEADER$
#

# MCA_pcompress_zlibng_CONFIG([action-if-can-compile],
#                           [action-if-cant-compile])
# ------------------------------------------------
AC_DEFUN([MCA_pmix_pcompress_zlibng_CONFIG],[
    AC_CONFIG_FILES([src/mca/pcompress/zlibng/Makefile])

    AC_ARG_WITH([zlibng],
                [AS_HELP_STRING([--with-zlibng=DIR],
                                [Search for zlib-ng headers and libraries in DIR ])])
    AC_ARG_WITH([zlibng-libdir],
                [AS_HELP_STRING([--with-zlibng-libdir=DIR],
                                [Search for zlib-ng libraries in DIR ])])

    pmix_zlibng_support=0

    OAC_CHECK_PACKAGE([zlibng],
                      [pcompress_zlibng],
                      [zlib-ng.h],
                      [z-ng],
                      [zng_deflate],
                      [pmix_zlibng_support=1],
                      [pmix_zlibng_support=0])

    if test ! -z "$with_zlibng" && test "$with_zlibng" != "no" && test "$pmix_zlibng_support" != "1"; then
        AC_MSG_WARN([ZLIB-NG SUPPORT REQUESTED AND NOT FOUND])
        AC_MSG_ERROR([CANNOT CONTINUE])
    fi

    AC_MSG_CHECKING([will zlib-ng support be built])
    AS_IF([test "$pmix_zlibng_support" = "1"],
          [$1
           AC_MSG_RESULT([yes])],
          [$2
           AC_MSG_RESULT([no])])

    PMIX_SUMMARY_ADD([External Packages], [ZLIBNG], [], [${pcompress_zlibng_SUMMARY}])

    # substitute in the things needed to build pcompress/zlibng
    AC_SUBST([pcompress_zlibng_CPPFLAGS])
    AC_SUBST([pcompress_zlibng_LDFLAGS])
    AC_SUBST([pcompress_zlibng_LIBS])

    PMIX_EMBEDDED_LIBS="$PMIX_EMBEDDED_LIBS $pcompress_zlibng_LIBS"
    PMIX_EMBEDDED_LDFLAGS="$PMIX_EMBEDDED_LDFLAGS $pcompress_zlibng_LDFLAGS"
    PMIX_EMBEDDED_CPPFLAGS="$PMIX_EMBEDDED_CPPFLAGS $pcompress_zlibng_CPPFLAGS"

])dnl