opencc-sys 0.4.3+1.3.1

OpenCC bindings for Rust
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149

package(default_visibility = ["//visibility:public"])

[
    genrule(
        name = "reverse_" + txt,
        srcs = [txt + ".txt"],
        outs = [txt + "Rev.txt"],
        cmd = "$(location //data/scripts:reverse) " +
              "$(SRCS) $(OUTS)",
        tools = ["//data/scripts:reverse"],
    )
    for txt in [
        "TWVariants",
        "HKVariants",
        "JPVariants",
    ]
]

TEXT_DICTS = glob(["*.txt"]) + [
    "TWVariantsRev.txt",
    "HKVariantsRev.txt",
    "JPVariantsRev.txt",
]

NON_BMP_TEXT_DICTS = [
    txt
    for txt in TEXT_DICTS
    if txt not in [
        "STCharacters.txt",
        "TSCharacters.txt",
    ]
]

[
    genrule(
        name = "generate_bin_" + txt[:-4],
        srcs = [txt],
        outs = [txt.replace(".txt", ".ocd2")],
        cmd = "$(location //src/tools:dict_converter) " +
              "--input $(location " + txt + ") " +
              "--output $(OUTS) " +
              "--from text " +
              "--to ocd2",
        tools = ["//src/tools:dict_converter"],
    )
    for txt in TEXT_DICTS
]

filegroup(
    name = "text_dictionaries",
    srcs = TEXT_DICTS,
)

filegroup(
    name = "binary_dictionaries",
    srcs = [txt.replace(".txt", ".ocd2") for txt in TEXT_DICTS],
)

[
    cc_test(
        name = "dictionary_" + txt[:-4] + "_test",
        size = "small",
        srcs = ["DictionaryTest.cpp"],
        local_defines = [
            "OPENCC_DICTIONARY_TEST_FILE=\\\"" + txt + "\\\"",
        ],
        data = [
            txt,
            txt.replace(".txt", ".ocd2"),
        ],
        deps = [
            "//src:lexicon",
            "//src:marisa_dict",
            "//src:utf8_util",
            "@bazel_tools//tools/cpp/runfiles",
            "@googletest//:gtest_main",
        ],
    )
    for txt in TEXT_DICTS
]

cc_test(
    name = "dictionary_TWPhrases_reverse_mapping_test",
    size = "small",
    srcs = ["DictionaryReverseMappingTest.cpp"],
    data = [
        "TWPhrases.txt",
        "TWPhrasesRev.txt",
    ],
    deps = [
        "//src:lexicon",
        "//src:utf8_util",
        "@bazel_tools//tools/cpp/runfiles",
        "@googletest//:gtest_main",
    ],
)

cc_test(
    name = "dictionary_TWPhrases_segmentation_test",
    size = "small",
    srcs = ["DictionaryTaiwanPhraseSegmentationTest.cpp"],
    data = [
        "STPhrases.txt",
        "TWPhrases.txt",
    ],
    deps = [
        "//src:lexicon",
        "//src:utf8_util",
        "@bazel_tools//tools/cpp/runfiles",
        "@googletest//:gtest_main",
    ],
)

test_suite(
    name = "dictionary_test",
    tests = [
        ":dictionary_" + txt[:-4] + "_test"
        for txt in TEXT_DICTS
    ] + [
        ":dictionary_TWPhrases_reverse_mapping_test",
        ":dictionary_TWPhrases_segmentation_test",
    ],
)

[
    cc_test(
        name = "dictionary_non_bmp_" + txt[:-4] + "_test",
        size = "small",
        srcs = ["DictionaryNonBmpTest.cpp"],
        local_defines = [
            "OPENCC_DICTIONARY_NON_BMP_TEST_FILE=\\\"" + txt + "\\\"",
        ],
        data = [txt],
        deps = [
            "//src:utf8_util",
            "@bazel_tools//tools/cpp/runfiles",
            "@googletest//:gtest_main",
        ],
    )
    for txt in NON_BMP_TEXT_DICTS
]

test_suite(
    name = "dictionary_non_bmp_test",
    tests = [
        ":dictionary_non_bmp_" + txt[:-4] + "_test"
        for txt in NON_BMP_TEXT_DICTS
    ],
)