openapi-tui 0.10.2

This TUI allows you to list and browse APIs described by the openapi specification.
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46

{
  system,
  pkgs,
  lockFile,
  fenix,
}: let
  cargoToml = builtins.fromTOML (builtins.readFile ../Cargo.toml);
  toolchain = fenix.packages.${system}.minimal.toolchain;
in
  (pkgs.makeRustPlatform {
    cargo = toolchain;
    rustc = toolchain;
  })
  .buildRustPackage rec {
    pname = cargoToml.package.name;
    version = cargoToml.package.version;

    src = ../.;

    cargoLock = {
      lockFile = lockFile;
    };

    nativeBuildInputs = with pkgs; [
      pkg-config
      makeWrapper
      rustfmt
    ];

    doCheck = true;
    CARGO_BUILD_INCREMENTAL = "false";
    RUST_BACKTRACE = "full";
    copyLibs = true;

    postInstall = ''
      wrapProgram $out/bin/${pname}
    '';

    meta = with pkgs.lib; {
      homepage = "https://github.com/zaghaghi/openapi-tui";
      description = "Terminal UI to list, browse and run APIs defined with OpenAPI v3.0 spec";
      license = licenses.mit;
      platforms = platforms.linux;
      mainProgram = pname;
    };
  }