oarust 0.8.6

GPU-first semantic computing engine written in Rust
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83

// Mechanically adapted from OA C++:
// source/cpp/lib/oa/ml/shader/compute/nn/attention/sdpaSoftmaxN32.slang

import storage;
import attributes;

struct PushConstants {
	uint scores_index;
	uint mask_index;
	uint probability_index;
	uint rows;
	uint columns;
	float scale;
	uint has_mask;
	uint causal;
};

[[vk::push_constant]] PushConstants push;
[[vk::binding(0, 0)]] RWByteAddressBuffer storage_buffers[];

groupshared float shared_maximum[32];
groupshared float shared_sum[32];

float reduce_maximum_32(float value, uint lane) {
	shared_maximum[lane] = value;
	GroupMemoryBarrierWithGroupSync();
	for (uint stride = 16; stride > 0; stride >>= 1) {
		if (lane < stride) {
			shared_maximum[lane] = max(shared_maximum[lane], shared_maximum[lane + stride]);
		}
		GroupMemoryBarrierWithGroupSync();
	}
	return shared_maximum[0];
}

float reduce_sum_32(float value, uint lane) {
	shared_sum[lane] = value;
	GroupMemoryBarrierWithGroupSync();
	for (uint stride = 16; stride > 0; stride >>= 1) {
		if (lane < stride) {
			shared_sum[lane] += shared_sum[lane + stride];
		}
		GroupMemoryBarrierWithGroupSync();
	}
	return shared_sum[0];
}

[kernel_name("sdpa_softmax_n32")]
[domain("ml")]
[variant("standard_n32")]
[dtype("f32")]
[status("experimental")]
[shader("compute")]
[numthreads(32, 1, 1)]
void main(uint3 group_id : SV_GroupID, uint3 group_thread_id : SV_GroupThreadID) {
	uint row = group_id.x;
	uint lane = group_thread_id.x;
	if (row >= push.rows) {
		return;
	}
	uint base = row * push.columns;
	uint query = row % push.columns;
	bool active = lane < push.columns;
	float value = -3.402823466e+38f;
	if (active) {
		value = load_f32(storage_buffers[push.scores_index], base + lane) * push.scale;
		if (push.has_mask != 0) {
			value += load_f32(storage_buffers[push.mask_index], base + lane);
		}
		if (push.causal != 0 && lane > query) {
			value = -3.402823466e+38f;
		}
	}
	float row_maximum = reduce_maximum_32(value, lane);
	float exponent = active ? exp(value - row_maximum) : 0.0;
	float inverse_sum = 1.0 / reduce_sum_32(exponent, lane);
	if (active) {
		store_f32(
			storage_buffers[push.probability_index],
			base + lane,
			exponent * inverse_sum);
	}
}