nirinit 0.2.2

A session manager for Niri, a scrollable-tiling Wayland compositor
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137

{
  description = "nirinit";

  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs/nixpkgs-unstable";
    fenix = {
      url = "github:nix-community/fenix";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  outputs =
    inputs:
    let
      inherit (inputs.nixpkgs) lib;
      inherit (inputs) self;
      systems = [
        "x86_64-linux"
        "aarch64-linux"
      ];

      eachSystem = f: lib.genAttrs systems (system: f inputs.nixpkgs.legacyPackages.${system});
    in
    {
      nixosModules = {
        nirinit =
          { config, pkgs, ... }:
          let
            inherit (lib)
              mkEnableOption
              mkPackageOption
              mkIf
              getExe
              ;
            cfg = config.services.nirinit;
          in
          {
            options = {
              services.nirinit = {
                enable = mkEnableOption "Nirinit";
                package = mkPackageOption self.packages.${pkgs.stdenv.hostPlatform.system} "nirinit" { };
                settings = lib.mkOption {
                  type = lib.types.submodule {
                    freeformType = (pkgs.formats.toml { }).type;
                    options = {
                      skip = lib.mkOption {
                        type = lib.types.submodule {
                          options = {
                            apps = lib.mkOption {
                              type = lib.types.listOf lib.types.str;
                              default = [ ];
                              description = "List of app IDs to skip during session restore";
                            };
                          };
                        };
                        default = { };
                        description = "Applications to skip";
                      };
                      launch = lib.mkOption {
                        type = lib.types.attrsOf lib.types.str;
                        default = { };
                        description = "Map app_id to actual launch command";
                      };
                    };
                  };
                  default = { };
                  description = "Configuration for nirinit";
                };
              };
            };
            config =
              let
                configFile = (pkgs.formats.toml { }).generate "nirinit-config.toml" cfg.settings;
              in
              mkIf cfg.enable {
                systemd.user.services.nirinit = {
                  enable = true;
                  description = "Nirinit";
                  wantedBy = [ "graphical-session.target" ];
                  partOf = [ "graphical-session.target" ];
                  wants = [ "graphical-session.target" ];
                  after = [ "graphical-session.target" ];
                  serviceConfig = {
                    Type = "simple";
                    Restart = "always";
                    ExecStart = "${getExe cfg.package} --config ${configFile}";
                    PrivateTmp = true;
                  };
                };
              };
          };

        default = self.nixosModules.nirinit;
      };

      packages = eachSystem (
        pkgs:
        let
          packageName = "nirinit";
        in
        {
          nirinit = pkgs.rustPlatform.buildRustPackage {
            pname = packageName;
            src = ./.;
            version = "0.2.2";

            cargoLock.lockFile = ./Cargo.lock;

            meta.mainProgram = packageName;
          };

          default = self.packages.${pkgs.stdenv.hostPlatform.system}.nirinit;
        }
      );
      devShells = eachSystem (
        pkgs:
        let
          fenixPkgs = inputs.fenix.packages.${pkgs.stdenv.hostPlatform.system};
        in
        {
          default = pkgs.mkShell {
            packages = [
              pkgs.nixfmt
              (fenixPkgs.complete.withComponents [
                "cargo"
                "clippy"
                "rust-src"
                "rustc"
                "rustfmt"
                "rust-analyzer"
              ])
            ];
          };
        }
      );
    };
}