nightshade 0.36.0

A cross-platform data-oriented game engine.
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50

#import nightshade::cull_common::{DrawIndexedIndirect, sphere_in_frustum}

struct SkinnedCullObject {
    bounds: vec4<f32>,
    command_index: u32,
    _pad0: u32,
    _pad1: u32,
    _pad2: u32,
};

struct SkinnedCullUniforms {
    frustum_planes: array<vec4<f32>, 6>,
    object_count: u32,
    _pad0: u32,
    _pad1: u32,
    _pad2: u32,
};

@group(0) @binding(0)
var<storage, read> cull_objects: array<SkinnedCullObject>;

@group(0) @binding(1)
var<storage, read_write> indirect_commands: array<DrawIndexedIndirect>;

@group(0) @binding(2)
var<storage, read_write> visible_indices: array<u32>;

@group(0) @binding(3)
var<uniform> cull: SkinnedCullUniforms;

@compute @workgroup_size(64)
fn main(@builtin(global_invocation_id) global_id: vec3<u32>) {
    let object_index = global_id.x;
    if object_index >= cull.object_count {
        return;
    }

    let object = cull_objects[object_index];
    if !sphere_in_frustum(cull.frustum_planes, object.bounds.xyz, object.bounds.w) {
        return;
    }

    let command_index = object.command_index;
    if command_index == 0xFFFFFFFFu {
        return;
    }
    let slot = atomicAdd(&indirect_commands[command_index].instance_count, 1u);
    let first_instance = indirect_commands[command_index].first_instance;
    visible_indices[first_instance + slot] = object_index;
}