nightshade-text 0.57.0

Text shaping, styling, and glyph geometry shared by the nightshade renderer and UI.
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45

set windows-shell := ["powershell.exe"]
export RUST_BACKTRACE := "1"

# Lists the available commands
@just:
    just --list

# Builds the crate and every example (compile gate)
build:
    cargo build -p nightshade-text --all-features --examples

# Runs the test suite
test:
    cargo test -p nightshade-text --all-features

# Clippy the crate and examples with warnings denied
lint:
    cargo clippy -p nightshade-text --all-targets --all-features -- -D warnings

# Clippy without shaping, so the geometry and styling types stay free of
# cosmic-text
lint-no-shaping:
    cargo clippy -p nightshade-text --no-default-features -- -D warnings

# Formats the crate
format:
    cargo fmt -p nightshade-text

# Builds the API documentation
doc:
    cargo doc -p nightshade-text --no-deps --all-features

# Lists the examples
[windows]
list:
    @Get-ChildItem examples -Filter *.rs | ForEach-Object { $_.BaseName }

# Lists the examples
[unix]
list:
    @ls examples/*.rs | xargs -n1 basename | sed 's/\.rs$//'

# Runs an example by name: `just run shape`
run name:
    cargo run -p nightshade-text --example {{ name }}