namaka 0.2.0

Snapshot testing for Nix based on haumea
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125

{
  description = "Snapshot testing for Nix based on haumea";

  inputs = {
    haumea = {
      url = "github:nix-community/haumea/v0.2.2";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";
  };

  outputs = { self, haumea, nixpkgs }:
    let
      inherit (nixpkgs) lib;
      inherit (lib)
        genAttrs
        importTOML
        licenses
        maintainers
        sourceByRegex
        ;

      eachSystem = f: genAttrs
        [
          "aarch64-darwin"
          "aarch64-linux"
          "x86_64-darwin"
          "x86_64-linux"
        ]
        (system: f nixpkgs.legacyPackages.${system});

      src = sourceByRegex self [
        "src(/.*)?"
        ''Cargo\.(toml|lock)''
        ''build\.rs''
      ];
    in
    {
      checks = self.lib.load {
        src = ./tests;
        inputs = {
          namaka = self.lib;
        };
      };

      formatter = eachSystem (pkgs: pkgs.nixpkgs-fmt);

      herculesCI.ciSystems = [
        "x86_64-linux"
        "aarch64-linux"
      ];

      lib = haumea.lib.load {
        src = ./nix;
        inputs = {
          inherit lib;
          haumea = haumea.lib;
        };
      };

      packages = eachSystem (pkgs:
        let
          inherit (pkgs)
            installShellFiles
            oniguruma
            pkg-config
            rustPlatform
            ;

          inherit (importTOML (src + "/Cargo.toml")) package;
        in
        {
          default = rustPlatform.buildRustPackage {
            pname = package.name;
            inherit (package) version;

            inherit src;

            cargoLock = {
              lockFile = src + "/Cargo.lock";
            };

            nativeBuildInputs = [
              installShellFiles
              pkg-config
            ];

            buildInputs = [
              oniguruma
            ];

            env = {
              GEN_ARTIFACTS = "artifacts";
              RUSTONIG_SYSTEM_LIBONIG = true;
            };

            postInstall = ''
              installManPage artifacts/*.1
              installShellCompletion artifacts/namaka.{bash,fish} --zsh artifacts/_namaka
            '';

            meta = {
              inherit (package) description;
              license = licenses.mpl20;
              maintainers = with maintainers; [ figsoda ];
            };
          };
        });

      templates = {
        default = {
          path = ./templates/default;
          description = "A Nix library";
        };
        minimal = {
          path = ./templates/minimal;
          description = "A Nix library that uses nixpkgs.lib instead of the entire nixpkgs";
        };
        subflake = {
          path = ./templates/subflake;
          description = "A Nix library that uses namaka in a subflake";
        };
      };
    };
}