mtk-rs 0.1.0-beta.4

Muse Toolkit
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55

struct TextInstance {
    pos: vec2<f32>,
    size: vec2<f32>,
    uv_pos: vec2<f32>,
    uv_size: vec2<f32>,
    color: vec4<f32>,
}

struct TextInstances {
    instances: array<TextInstance>,
}

@group(0) @binding(0) var<storage, read> instance_data: TextInstances;
@group(0) @binding(1) var t_atlas: texture_2d<f32>;
@group(0) @binding(2) var s_atlas: sampler;

struct PushConstants {
    screen_size: vec2<f32>,
}
var<immediate> pc: PushConstants;

struct VertexOutput {
    @builtin(position) clip_position: vec4<f32>,
    @location(0) color: vec4<f32>,
    @location(1) uv: vec2<f32>,
}

@vertex
fn vs_main(
    @builtin(vertex_index) in_vertex_index: u32,
    @builtin(instance_index) in_instance_index: u32,
) -> VertexOutput {
    let instance = instance_data.instances[in_instance_index];

    var positions = array<vec2<f32>, 6>(
        vec2<f32>(0.0, 0.0), vec2<f32>(1.0, 0.0), vec2<f32>(0.0, 1.0),
        vec2<f32>(0.0, 1.0), vec2<f32>(1.0, 0.0), vec2<f32>(1.0, 1.0)
    );
    let pos = positions[in_vertex_index];

    let screen_pos = instance.pos + pos * instance.size;
    let clip_pos = vec2<f32>(screen_pos.x / pc.screen_size.x * 2.0 - 1.0, 1.0 - screen_pos.y / pc.screen_size.y * 2.0);

    var out: VertexOutput;
    out.clip_position = vec4<f32>(clip_pos, 0.0, 1.0);
    out.color = instance.color;
    out.uv = instance.uv_pos + pos * instance.uv_size;
    return out;
}

@fragment
fn fs_main(in: VertexOutput) -> @location(0) vec4<f32> {
    let sample = textureSample(t_atlas, s_atlas, in.uv);
    return vec4<f32>(sample.rgb * in.color.rgb, sample.a * in.color.a);
}