mistralrs-quant 0.8.1

Fast, flexible LLM inference.
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227

#include "utils.metal"

template <typename T, typename U, int N = WorkPerThread<T>::n>
[[kernel]] void copy_s(device const T *src [[buffer(0)]],
                       device U *dst [[buffer(1)]], constant uint &size,
                       uint index [[thread_position_in_grid]]) {
  index *= N;
  for (int i = 0; i < N && (index + i) < size; ++i) {
    dst[index + i] = static_cast<U>(src[0]);
  }
}

template <typename T, typename U, int N = WorkPerThread<T>::n>
[[kernel]] void copy_v(device const T *src [[buffer(0)]],
                       device U *dst [[buffer(1)]], constant uint &size,
                       uint index [[thread_position_in_grid]]) {
  index *= N;
  for (int i = 0; i < N && (index + i) < size; ++i) {
    dst[index + i] = static_cast<U>(src[index + i]);
  }
}

template <typename T, typename U, int N = WorkPerThread<T>::n>
[[kernel]] void copy_s2(device const T *src [[buffer(0)]],
                        device U *dst [[buffer(1)]], constant int64_t &size,
                        uint2 index [[thread_position_in_grid]],
                        uint2 grid_dim [[threads_per_grid]]) {
  auto offset = N * (index.x + grid_dim.x * int64_t(index.y));
  for (int i = 0; i < N && (offset + i) < size; ++i) {
    dst[offset + i] = static_cast<U>(src[0]);
  }
}

template <typename T, typename U, int N = WorkPerThread<T>::n>
[[kernel]] void copy_v2(device const T *src [[buffer(0)]],
                        device U *dst [[buffer(1)]], constant int64_t &size,
                        uint2 index [[thread_position_in_grid]],
                        uint2 grid_dim [[threads_per_grid]]) {
  auto offset = N * (index.x + grid_dim.x * int64_t(index.y));
  for (int i = 0; i < N && (offset + i) < size; ++i) {
    dst[offset + i] = static_cast<U>(src[offset + i]);
  }
}

template <typename T, typename U, typename IdxT = int64_t>
[[kernel]] void copy_g_nd1(device const T *src [[buffer(0)]],
                           device U *dst [[buffer(1)]],
                           constant const int64_t &src_stride [[buffer(3)]],
                           uint index [[thread_position_in_grid]]) {
  auto src_idx = elem_to_loc_1<IdxT>(index, src_stride);
  dst[index] = static_cast<U>(src[src_idx]);
}

template <typename T, typename U, typename IdxT = int64_t>
[[kernel]] void copy_g_nd2(device const T *src [[buffer(0)]],
                           device U *dst [[buffer(1)]],
                           constant const int64_t *src_strides [[buffer(3)]],
                           uint2 index [[thread_position_in_grid]],
                           uint2 grid_dim [[threads_per_grid]]) {
  auto src_idx = elem_to_loc_2<IdxT>(index, src_strides);
  IdxT dst_idx = index.x + IdxT(grid_dim.x) * index.y;
  dst[dst_idx] = static_cast<U>(src[src_idx]);
}

template <typename T, typename U, typename IdxT = int64_t>
[[kernel]] void copy_g_nd3(device const T *src [[buffer(0)]],
                           device U *dst [[buffer(1)]],
                           constant const int64_t *src_strides [[buffer(3)]],
                           uint3 index [[thread_position_in_grid]],
                           uint3 grid_dim [[threads_per_grid]]) {
  auto src_idx = elem_to_loc_3<IdxT>(index, src_strides);
  IdxT dst_idx =
      index.x + IdxT(grid_dim.x) * (index.y + IdxT(grid_dim.y) * index.z);
  dst[dst_idx] = static_cast<U>(src[src_idx]);
}

template <typename T, typename U, int N = 1, typename IdxT = int64_t>
[[kernel]] void copy_g(device const T *src [[buffer(0)]],
                       device U *dst [[buffer(1)]],
                       constant const int *src_shape [[buffer(2)]],
                       constant const int64_t *src_strides [[buffer(3)]],
                       constant const int &ndim [[buffer(5)]],
                       uint3 index [[thread_position_in_grid]],
                       uint3 grid_dim [[threads_per_grid]]) {
  auto src_idx = elem_to_loc<IdxT>({N * index.x, index.y, index.z}, src_shape,
                                   src_strides, ndim);
  if (N == 1) {
    IdxT dst_idx =
        index.x + grid_dim.x * (index.y + IdxT(grid_dim.y) * index.z);
    dst[dst_idx] = static_cast<U>(src[src_idx]);
    return;
  }
  auto xshape = src_shape[ndim - 1];
  IdxT dst_idx = N * index.x + xshape * (index.y + IdxT(grid_dim.y) * index.z);
  auto src_xstride = src_strides[ndim - 1];
  for (int i = 0; i < N && (int(N * index.x) + i) < xshape; ++i) {
    dst[dst_idx + i] = static_cast<U>(src[src_idx]);
    src_idx += src_xstride;
  }
}

template <typename T, typename U, typename IdxT = int64_t>
[[kernel]] void copy_gg_nd1(device const T *src [[buffer(0)]],
                            device U *dst [[buffer(1)]],
                            constant const int64_t &src_stride [[buffer(3)]],
                            constant const int64_t &dst_stride [[buffer(4)]],
                            uint index [[thread_position_in_grid]]) {
  auto src_idx = elem_to_loc_1<IdxT>(index, src_stride);
  auto dst_idx = elem_to_loc_1<IdxT>(index, dst_stride);
  dst[dst_idx] = static_cast<U>(src[src_idx]);
}

template <typename T, typename U, typename IdxT = int64_t>
[[kernel]] void copy_gg_nd2(device const T *src [[buffer(0)]],
                            device U *dst [[buffer(1)]],
                            constant const int64_t *src_strides [[buffer(3)]],
                            constant const int64_t *dst_strides [[buffer(4)]],
                            uint2 index [[thread_position_in_grid]]) {
  auto src_idx = elem_to_loc_2<IdxT>(index, src_strides);
  auto dst_idx = elem_to_loc_2<IdxT>(index, dst_strides);
  dst[dst_idx] = static_cast<U>(src[src_idx]);
}

template <typename T, typename U, typename IdxT = int64_t>
[[kernel]] void copy_gg_nd3(device const T *src [[buffer(0)]],
                            device U *dst [[buffer(1)]],
                            constant const int64_t *src_strides [[buffer(3)]],
                            constant const int64_t *dst_strides [[buffer(4)]],
                            uint3 index [[thread_position_in_grid]]) {
  auto src_idx = elem_to_loc_3<IdxT>(index, src_strides);
  auto dst_idx = elem_to_loc_3<IdxT>(index, dst_strides);
  dst[dst_idx] = static_cast<U>(src[src_idx]);
}

template <typename T, typename U, int N = 1, typename IdxT = int64_t>
[[kernel]] void copy_gg(device const T *src [[buffer(0)]],
                        device U *dst [[buffer(1)]],
                        constant const int *src_shape [[buffer(2)]],
                        constant const int64_t *src_strides [[buffer(3)]],
                        constant const int64_t *dst_strides [[buffer(4)]],
                        constant const int &ndim [[buffer(5)]],
                        uint3 index [[thread_position_in_grid]]) {
  auto idx = elem_to_loc_2_nd<IdxT>({N * index.x, index.y, index.z}, src_shape,
                                    src_strides, dst_strides, ndim);
  if (N == 1) {
    dst[idx.y] = static_cast<U>(src[idx.x]);
    return;
  }
  IdxT src_xstride = src_strides[ndim - 1];
  IdxT dst_xstride = dst_strides[ndim - 1];
  auto xshape = src_shape[ndim - 1];
  for (int i = 0; i < N && (int(N * index.x) + i) < xshape; ++i) {
    dst[idx.y] = static_cast<U>(src[idx.x]);
    idx.x += src_xstride;
    idx.y += dst_xstride;
  }
}

template <typename T, typename U, typename IdxT = int64_t>
[[kernel]] void
copy_gg_dynamic_nd1(device const T *src [[buffer(0)]],
                    device U *dst [[buffer(1)]],
                    constant const int64_t &src_stride [[buffer(3)]],
                    constant const int64_t &dst_stride [[buffer(4)]],
                    constant const int64_t &src_offset [[buffer(6)]],
                    constant const int64_t &dst_offset [[buffer(7)]],
                    uint index [[thread_position_in_grid]]) {
  auto src_idx = elem_to_loc_1<IdxT>(index, src_stride);
  auto dst_idx = elem_to_loc_1<IdxT>(index, dst_stride);
  dst[dst_idx + dst_offset] = src[src_idx + src_offset];
}

template <typename T, typename U, typename IdxT = int64_t>
[[kernel]] void
copy_gg_dynamic_nd2(device const T *src [[buffer(0)]],
                    device U *dst [[buffer(1)]],
                    constant const int64_t *src_strides [[buffer(3)]],
                    constant const int64_t *dst_strides [[buffer(4)]],
                    constant const int64_t &src_offset [[buffer(6)]],
                    constant const int64_t &dst_offset [[buffer(7)]],
                    uint2 index [[thread_position_in_grid]]) {
  auto src_idx = elem_to_loc_2<IdxT>(index, src_strides);
  auto dst_idx = elem_to_loc_2<IdxT>(index, dst_strides);
  dst[dst_idx + dst_offset] = src[src_idx + src_offset];
}

template <typename T, typename U, typename IdxT = int64_t>
[[kernel]] void
copy_gg_dynamic_nd3(device const T *src [[buffer(0)]],
                    device U *dst [[buffer(1)]],
                    constant const int64_t *src_strides [[buffer(3)]],
                    constant const int64_t *dst_strides [[buffer(4)]],
                    constant const int64_t &src_offset [[buffer(6)]],
                    constant const int64_t &dst_offset [[buffer(7)]],
                    uint3 index [[thread_position_in_grid]]) {
  auto src_idx = elem_to_loc_3<IdxT>(index, src_strides);
  auto dst_idx = elem_to_loc_3<IdxT>(index, dst_strides);
  dst[dst_idx + dst_offset] = src[src_idx + src_offset];
}

template <typename T, typename U, int N = 1, typename IdxT = int64_t>
[[kernel]] void
copy_gg_dynamic(device const T *src [[buffer(0)]], device U *dst [[buffer(1)]],
                constant const int *src_shape [[buffer(2)]],
                constant const int64_t *src_strides [[buffer(3)]],
                constant const int64_t *dst_strides [[buffer(4)]],
                constant const int &ndim [[buffer(5)]],
                constant const int64_t &src_offset [[buffer(6)]],
                constant const int64_t &dst_offset [[buffer(7)]],
                uint3 index [[thread_position_in_grid]]) {
  src += src_offset;
  dst += dst_offset;
  auto idx = elem_to_loc_2_nd<IdxT>({N * index.x, index.y, index.z}, src_shape,
                                    src_strides, dst_strides, ndim);
  if (N == 1) {
    dst[idx.y] = src[idx.x];
    return;
  }
  IdxT src_xstride = src_strides[ndim - 1];
  IdxT dst_xstride = dst_strides[ndim - 1];
  auto xshape = src_shape[ndim - 1];
  for (int i = 0; i < N && (int(N * index.x) + i) < xshape; ++i) {
    dst[idx.y] = src[idx.x];
    idx.x += src_xstride;
    idx.y += dst_xstride;
  }
}