meta-ast 0.4.0

Polyglot static-analysis engine: extract symbols and cross-language dependency graphs from 8 supported source languages, with optional MetaCall deployment manifest generation.
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130

#
#	CMake Find Dot NET Engine by Parra Studios
#	CMake script to find DotNET Engine.
#
#	Copyright (C) 2016 - 2026 Vicente Eduardo Ferrer Garcia <vic798@gmail.com>
#
#	Licensed under the Apache License, Version 2.0 (the "License");
#	you may not use this file except in compliance with the License.
#	You may obtain a copy of the License at
#
#		http://www.apache.org/licenses/LICENSE-2.0
#
#	Unless required by applicable law or agreed to in writing, software
#	distributed under the License is distributed on an "AS IS" BASIS,
#	WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
#	See the License for the specific language governing permissions and
#	limitations under the License.
#

# Find DotNET library and include paths
#
# DOTNET_FOUND - True if DotNET was found
# DOTNET_COMMAND - Return DotNET command

# Prevent vervosity if already included
include(FindPackageHandleStandardArgs)
if(DOTNET_FOUND)
	set(DOTNET_FIND_QUIETLY TRUE)
endif()

# Define dotnet command
set(DOTNET_COMMAND dotnet CACHE FILEPATH "Path of .NET Core command")

# Detect dotnet command
execute_process(COMMAND ${DOTNET_COMMAND}
	RESULT_VARIABLE DOTNET_COMMAND_RESULT
	OUTPUT_QUIET
)

# Set found variable (TODO: Review 129 state in Debian)
if(DOTNET_COMMAND_RESULT EQUAL 0 OR DOTNET_COMMAND_RESULT EQUAL 129)
	set(DOTNET_FOUND TRUE)
else()
	set(DOTNET_FOUND FALSE)
endif()

# Detect dotnet variables
if(DOTNET_FOUND)
	# Detect dotnet version
	execute_process(COMMAND ${DOTNET_COMMAND} --version
		RESULT_VARIABLE DOTNET_COMMAND_RESULT
		OUTPUT_VARIABLE DOTNET_COMMAND_OUTPUT
		OUTPUT_STRIP_TRAILING_WHITESPACE
	)

	if(DOTNET_COMMAND_RESULT EQUAL 0)
		set(DOTNET_VERSION "${DOTNET_COMMAND_OUTPUT}")

		# Detect dotnet migrate command
		if(DOTNET_VERSION VERSION_GREATER "1.1" OR DOTNET_VERSION VERSION_EQUAL "1.1")
			set(DOTNET_MIGRATE 1)
		else()
			set(DOTNET_MIGRATE 0)
		endif()

		mark_as_advanced(DOTNET_COMMAND DOTNET_VERSION DOTNET_MIGRATE)
	endif()
endif()

if(NOT DOTNET_CORE_PATH AND DOTNET_COMMAND)
	execute_process(
		COMMAND ${DOTNET_COMMAND} --list-runtimes
		OUTPUT_VARIABLE DOTNET_RUNTIMES
		OUTPUT_STRIP_TRAILING_WHITESPACE
	)

	string(REPLACE "\n" ";" DOTNET_RUNTIMES "${DOTNET_RUNTIMES}")
	string(REPLACE "\\" "/" DOTNET_RUNTIMES "${DOTNET_RUNTIMES}")

	set(HIGHEST_VERSION "")
	set(RUNTIME_PATH "")

	foreach(LINE ${DOTNET_RUNTIMES})
		if(LINE MATCHES "Microsoft\\.NETCore\\.App")

			# Extract version
			string(REGEX REPLACE
				"Microsoft\\.NETCore\\.App[ ]+([0-9\\.]+)[ ].*"
				"\\1"
				VERSION
				"${LINE}"
			)

			# Extract base path
			string(REGEX MATCH "\\[([^]]+)\\]" LINE_MATCH "${LINE}")

			if(LINE_MATCH)
				string(REGEX REPLACE "^\\[|\\]$" "" BASE_PATH "${LINE_MATCH}")
			endif()

			set(FULL_PATH "${BASE_PATH}/${VERSION}")

			if(EXISTS "${FULL_PATH}/libcoreclr.so")
				# Pick highest version
				if(HIGHEST_VERSION STREQUAL "" OR VERSION VERSION_GREATER HIGHEST_VERSION)
					set(HIGHEST_VERSION ${VERSION})
					set(RUNTIME_PATH ${FULL_PATH})
				endif()
			endif()
		endif()
	endforeach()

	if(EXISTS "${RUNTIME_PATH}/libcoreclr.so")
		set(DOTNET_CORE_PATH "${RUNTIME_PATH}" CACHE PATH "Dotnet runtime path" FORCE)
	endif()
endif()

if(DOTNET_CORE_PATH)
	set(DOTNET_CORE_LIBRARIES "${DOTNET_CORE_PATH}/libcoreclr.so")
endif()

find_package_handle_standard_args(DotNET
    REQUIRED_VARS DOTNET_COMMAND DOTNET_CORE_PATH
)

mark_as_advanced(
	DOTNET_COMMAND
	DOTNET_CORE_PATH
	DOTNET_CORE_LIBRARIES
)