meganeura 0.2.0

E-graph optimized neural network training on Blade
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55

// Precompute rsqrt for RmsNorm: rsqrt[row] = inverseSqrt(sum(x²)/K + eps)
//
// Dispatch: [rows, 1, 1], WG=256
// Each workgroup cooperatively computes rsqrt for one row using
// shared-memory tree reduction over the K dimension.

struct Params {
    rows: u32,
    cols: u32,
    eps_bits: u32,
    _pad: u32,
}

var<storage> src: array<f32>;              // X [rows, cols]
var<storage, read_write> dst: array<f32>;  // rsqrt [rows]
var<uniform> params: Params;
var<workgroup> wg_sum: array<f32, 256>;

@compute @workgroup_size(256)
fn main(@builtin(workgroup_id) wgid: vec3<u32>, @builtin(local_invocation_id) lid: vec3<u32>) {
    let row = wgid.x;
    let tid = lid.x;
    let cols = params.cols;
    let eps = bitcast<f32>(params.eps_bits);

    if row >= params.rows { return; }

    // Cooperative sum of squares: each thread sums a stride of the row
    let offset = row * cols;
    var ss = 0.0;
    var j = tid;
    loop {
        if j >= cols { break; }
        let v = src[offset + j];
        ss += v * v;
        j += 256u;
    }
    wg_sum[tid] = ss;
    workgroupBarrier();

    // Tree reduction
    var stride = 128u;
    loop {
        if stride == 0u { break; }
        if tid < stride {
            wg_sum[tid] += wg_sum[tid + stride];
        }
        workgroupBarrier();
        stride >>= 1u;
    }

    if tid == 0u {
        dst[row] = inverseSqrt(wg_sum[0] / f32(cols) + eps);
    }
}