mdev-parser 0.1.1

Parse the Busybox mdev configuration file
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44

number = @{ ASCII_DIGIT+ }
majmin = ${ "@" ~ number ~ "," ~ number ~ (("-" ~ number) | !"-") }

regex = @{ (!WHITESPACE ~ !";" ~ ASCII)+ }

envvar = @{ (ASCII_ALPHA_UPPER ~ (ASCII_ALPHA_UPPER | "_")*) }

stop = { "-" }

env_match = ${ envvar ~ "=" ~ regex ~ ";" }

device_regex = ${ (("$" ~ envvar ~ "=") | !"$") ~ regex }

name = @{ ASCII_ALPHA+ }
usergroup = { name ~ ":" ~ name }

mode = { '0'..'7'{3} }

// TODO:  maybe find a better definition
path_char = _{ !"/" ~ !"\x00" ~ !WHITESPACE ~ ANY }
path = @{ "/"? ~ (path_char+ ~ "/")* ~ path_char+? }

move_to = ${ "=" ~ path }
symlink = ${ ">" ~ path }
prevent = { "!" }
on_creation = ${ move_to | symlink | prevent }

after = { "@" }
before = { "$" }
both = { "*" }
when = { after | before | both }

exec = ${ when ~ path }
arg = @{ (!WHITESPACE ~ !NEWLINE ~ ASCII)+ }
command = { exec ~ arg* }

// matcher is separated to apply the $ modifier
matcher = ${ stop? ~ env_match* ~ ((!"@" ~ device_regex) | majmin) }
rule = { matcher ~ usergroup ~ mode ~ on_creation? ~ command? }
comment = ${ "#" ~ ANY* ~ (NEWLINE | EOI) }
empty = { WHITESPACE* ~ (NEWLINE | EOI) }
line = { (comment | empty | (rule ~ (NEWLINE | EOI))) }

WHITESPACE = _{ " " | "\t" }