mdbook 0.5.2

Creates a book from markdown files
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69

// This GUI test checks sidebar hide/show and also its behaviour on smaller
// width.

go-to: |DOC_PATH| + "all-summary/index.html"
set-window-size: (1100, 600)
// Need to reload for the new size to be taken account by the JS.
reload:

store-value: (content_indent, 308)
store-value: (sidebar_storage_value, "mdbook-sidebar")
store-value: (sidebar_storage_hidden_value, "hidden")
store-value: (sidebar_storage_displayed_value, "visible")

define-function: (
    "hide-sidebar",
    [],
    block {
        assert-position: ("#mdbook-page-wrapper", {"x": |content_indent|})

        // We now hide the sidebar.
        click: "#mdbook-sidebar-toggle"
        wait-for-css: ("#mdbook-sidebar", {"display": "none"})
        assert-local-storage: {|sidebar_storage_value|: |sidebar_storage_hidden_value|}
    },
)

define-function: (
    "show-sidebar",
    [],
    block {
        assert-css: ("#mdbook-sidebar", {"display": "none"})
        assert-position: ("#mdbook-page-wrapper", {"x": 0})

        // We expand the sidebar.
        click: "#mdbook-sidebar-toggle"
        wait-for-css-false: ("#mdbook-sidebar", {"display": "none"})
        // `transform` is 0.3s so we need to wait a bit (0.5s) to ensure the animation is done.
        wait-for: 5000
        assert-css-false: ("#mdbook-sidebar", {"transform": "matrix(1, 0, 0, 1, -308, 0)"})
        // The page content should be moved to the right.
        assert-position: ("#mdbook-page-wrapper", {"x": |content_indent|})
        assert-local-storage: {|sidebar_storage_value|: |sidebar_storage_displayed_value|}
    },
)

// Since the sidebar is visible, we should be able to find this text.
assert-find-text: ("3. P1 C1", {"case-sensitive": true})
call-function: ("hide-sidebar", {})
// Text should not be findeable anymore since the sidebar is collapsed.
assert-find-text-false: ("3. P1 C1", {"case-sensitive": true})
call-function: ("show-sidebar", {})
// We should be able to find this text again.
assert-find-text: ("3. P1 C1", {"case-sensitive": true})

// We now test on smaller width to ensure that the sidebar is collapsed by default.
set-window-size: (900, 600)
reload:
call-function: ("show-sidebar", {})
call-function: ("hide-sidebar", {})

// We now test that if the sidebar is considered open and we reload the page, since
// the width is small, it will still be collapsed.
set-local-storage: {|sidebar_storage_value|: |sidebar_storage_displayed_value|}
reload:
// The stored value shouldn't have changed.
assert-local-storage: {|sidebar_storage_value|: |sidebar_storage_displayed_value|}
// But the sidebar should be hidden anyway.
assert-css: ("#mdbook-sidebar", {"display": "none"})
assert-position: ("#mdbook-page-wrapper", {"x": 0})