mailmodel 0.1.5

A proof-of-concept mail viewer writting with Qt using QML
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142

import QtQuick 2.7
import QtQuick.Controls 1.4
import QtQuick.Controls.Styles 1.4
import QtQuick.Layouts 1.2
import QtQuick.Window 2.2
import RustCode 1.0

Window {
    visible: true
    width: 1024
    height: 800
    title: qsTr("Mail Viewer")

    MailModel {
        id: mailmodel
        configFile: mailConfigFile
    }

    SystemPalette {
        id: palette
        colorGroup: SystemPalette.Active
    }

    FontMetrics {
        id: systemFont
    }

    ColumnLayout {
        anchors.fill: parent
        SplitView {
            Layout.fillHeight: true
            Layout.fillWidth: true
            handleDelegate: Rectangle {
                width: 3
                color: palette.window
            }
            TreeView {
                id: folders
                headerVisible: false
                frameVisible: false
                TableViewColumn {
                    title: "Name"
                    role: "name"
                    width: folders.width - 20
                    delegate: Text {
                        text: icon(styleData.value) + " " + styleData.value
                        verticalAlignment: Text.AlignVCenter
                    }
                }
                style: TreeViewStyle {
                    highlightedTextColor: palette.highlightedText
                    backgroundColor: palette.base
                    alternateBackgroundColor: palette.alternateBase
                }
                rowDelegate: Rectangle {
                    height: 2.5 * systemFont.font.pixelSize
                    color: styleData.selected
                               ? folders.activeFocus
                                   ? palette.highlight
                                   : Qt.lighter(palette.highlight, 1.5)
                               : rowMouse.containsMouse
                                   ? Qt.lighter(palette.highlight, 1.8)
                                   : palette.base
                    MouseArea {
                        id: rowMouse
                        anchors.fill: parent
                        hoverEnabled: true
                        acceptedButtons: Qt.NoButton
                    }
                }
                model: mailmodel.folders
                onCurrentIndexChanged: {
                    var parent = mailmodel.folders.parent(currentIndex);
                    var path = mailmodel.folders.name(currentIndex);
                    var delimiter = mailmodel.folders.delimiter(currentIndex);
                    while (parent.valid) {
                        path = mailmodel.folders.name(parent) + delimiter + path;
                        parent = mailmodel.folders.parent(parent);
                    }
                    path = path.substr(2);
                    mailmodel.currentFolder = path;
                }
            }
            ThreadsView {
                id: threads
                onCurrentUidChanged: if (currentUid !== undefined) {
                    mailmodel.setEmail(currentUid)
                }
                onFilterChanged: mailmodel.folder_threads.setFilter(filter)
            }
            Email {
            }
            Component.onCompleted: threads.width = threads.Layout.preferredWidth
        }
        Rectangle {
            visible: label.text
            color: "yellow"
            width: childrenRect.width
            height: childrenRect.height
            Label {
                id: label
                text: mailmodel.folder_threads.error || ""
            }
        }
    }
    function expand(treeview, index) {
        treeview.expand(index);
        var rowCount = treeview.model.rowCount(index);
        var row;
        for (row = 0; row < rowCount; ++row) {
            expand(treeview, treeview.model.index(row, 0, index));
        }
    }
    function expandRecursive(treeview, index) {
        treeview.expand(index);
        var rowCount = treeview.model.rowCount(index);
        var row;
        for (row = 0; row < rowCount; ++row) {
            expandRecursive(treeview, treeview.model.index(row, 0, index));
        }
    }
    function expandAll(treeview) {
        expandRecursive(treeview, treeview.rootIndex);
    }
    Component.onCompleted: {
        folders.model.modelReset.connect(function () {
            expandAll(folders);
        });
    }
    function icon(name) {
        if (name.toLowerCase() === "inbox") {
            return "📥";
        }
        if (name.toLowerCase() === "trash") {
            return "🗑";
        }
        if (name.toLowerCase() === "outbox") {
            return "📤";
        }
        return "📂";
    }
}