mailmodel 0.1.5

A proof-of-concept mail viewer writting with Qt using QML
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138

import QtQuick 2.7
import QtQuick.Controls 1.4
import QtQuick.Layouts 1.2
import QtQml.Models 2.3

Item {
    readonly property var currentUid: folder.currentIndex.valid ? folder.model.uid(folder.currentIndex) : undefined
    readonly property string filter: filterField.text
    QtObject {
        id: p
        property var currentIndex
        property var selectedIndexes
    }
    Layout.preferredWidth: 300
    TextField {
        id: filterField
        width: parent.width
        placeholderText: qsTr("Search this folder")
    }
    TreeView {
        id: folder
        headerVisible: false
        frameVisible: false
        y: filterField.height
        width: parent.width
        height: parent.height - filterField.height
        model: mailmodel.folder_threads
        selectionMode: SelectionMode.ExtendedSelection
        selection: ItemSelectionModel {
            model: mailmodel.folder_threads
        }
        onExpanded: expandRecursive(folder, index)
        TableViewColumn {
            title: "Mail"
            role: "subject"
            width: folder.width - 20
        }
        itemDelegate: delegate
        rowDelegate: Rectangle {
            height: 3 * systemFont.font.pixelSize
            color: styleData.selected
                ? folder.activeFocus
                    ? palette.highlight
                    : Qt.lighter(palette.highlight, 1.5)
                : rowMouse.containsMouse
                    ? styleData.alternate
                        ? Qt.darker(palette.alternateBase, 1.02)
                        : Qt.darker(palette.base, 1.02)
                    : styleData.alternate ? palette.alternateBase : palette.base
            MouseArea {
                id: rowMouse
                anchors.fill: parent
                hoverEnabled: true
                acceptedButtons: Qt.NoButton
            }
        }
        section.property: "section"
        section.delegate: Rectangle {
            color: palette.mid
            height: 1.5 * section_text.font.pixelSize
            width: folder.width
            Text {
                id: section_text
                anchors.fill: parent
                font.bold: true
                text: section
                verticalAlignment: Text.AlignVCenter
            }
        }
    }
    Component {
        id: delegate
        Item {
            property color textColor: styleData.selected
                    ? folder.activeFocus ? palette.highlightedText : palette.text
                    : (valid() && mailmodel.folder_threads.seen(styleData.index)) ? palette.text : palette.highlight
            width: parent.width
            function valid() {
                return styleData.index && styleData.index.valid
            }
            Text {
                id: s
                text: styleData.value || ""
                color: textColor
                textFormat: Text.PlainText
                anchors.left: parent.left
                anchors.right: parent.right
                anchors.top: parent.top
                elide: Text.ElideRight
            }
            Text {
                id: f
                text: valid() ? mailmodel.folder_threads.from(styleData.index) : ""
                color: textColor
                textFormat: Text.PlainText
                width: s.width - d.width
                anchors.top: s.bottom
                anchors.left: parent.left
                anchors.bottom: parent.bottom
                font.italic: true
                elide: Text.ElideRight
            }
            Text {
                id: d
                text: valid() ? mailmodel.folder_threads.date(styleData.index) : ""
                color: textColor
                textFormat: Text.PlainText
                width: contentWidth
                anchors.top: s.bottom
                anchors.right: parent.right
                anchors.bottom: parent.bottom
                font.italic: true
                horizontalAlignment: Text.AlignRight
            }
        }
    }
    function saveSelection() {
        p.currentIndex = folder.selection.currentIndex;
        p.selectedIndexes = folder.selection.selectedIndexes;
    }
    function restoreSelection() {
        var s;
        for (s in p.selectedIndexes) {
            folder.selection.select(s, ItemSelectionModel.Select);
        }
        folder.selection.setCurrentIndex(p.currentIndex, ItemSelectionModel.Select);
    }
    Component.onCompleted: {
        folder.model.modelReset.connect(function () {
        });
        folder.model.layoutAboutToBeChanged.connect(saveSelection);
        folder.model.layoutChanged.connect(function () {
            restoreSelection();
        });
        folder.model.rowsInserted.connect(function (parent) {
        });
    }
}