lumen 2.16.0

lumen is a command-line tool that uses AI to generate commit messages, summarise git diffs or past commits, and more.
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67

{
  description = "A command-line tool that uses AI to streamline your git workflow - from generating commit messages to explaining complex changes.";

  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";
    flake-utils.url = "github:numtide/flake-utils";
    fenix = {
      url = "github:nix-community/fenix";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  outputs = {
    self,
    nixpkgs,
    flake-utils,
    fenix,
    ...
  }:
    flake-utils.lib.eachDefaultSystem (system: let
      pkgs = import nixpkgs {inherit system;};
      rustToolchain = fenix.packages.${system}.stable.withComponents [
        "cargo"
        "clippy"
        "rustc"
        "rustfmt"
        "rust-src"
      ];
      rust-analyzer = fenix.packages.${system}.rust-analyzer;
    in {
      packages = {
        lumen = let
          manifest = (pkgs.lib.importTOML ./Cargo.toml).package;
        in
          pkgs.rustPlatform.buildRustPackage {
            pname = manifest.name;
            version = manifest.version;

            cargoLock.lockFile = ./Cargo.lock;

            src = pkgs.lib.cleanSource ./.;

            nativeBuildInputs = [pkgs.pkg-config pkgs.perl];
            buildInputs = [pkgs.openssl];
            doCheck = false;
          };
        default = self.packages.${system}.lumen;
      };

      devShells.default = pkgs.mkShell {
        nativeBuildInputs = [
          rustToolchain
          rust-analyzer
          pkgs.pkg-config
          pkgs.perl
        ];
        buildInputs = [
          pkgs.openssl
        ];
      };
    })
    // {
      overlays.default = final: prev: {
        inherit (self.packages.${final.system}) lumen;
      };
    };
}