ltrait 0.7.1

Yet Another Fuzzy Finder (Builder) for OS Wide, inspired from vim-fall and ddu.vim (and xmonad)
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127

{
  description = "A very basic flake";

  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs?ref=nixos-unstable";
    rust-overlay.url = "github:oxalica/rust-overlay";
    rust-overlay.inputs.nixpkgs.follows = "nixpkgs";

    clippy-reviewdog-filter-src = {
      url = "github:qnighy/clippy-reviewdog-filter";
      flake = false;
    };
  };

  outputs =
    inputs@{ self, nixpkgs, ... }:
    let
      system = "x86_64-linux";

      pkgs = import nixpkgs {
        inherit system;
        overlays = [
          inputs.rust-overlay.overlays.default
          (self: super: {
            # TODO: waiting for https://github.com/NixOS/nixpkgs/pull/391472
            # HACK:
            cargo-codspeed = super.rustPlatform.buildRustPackage rec {
              pname = "cargo-codspeed";
              version = "2.9.1";

              src = super.fetchFromGitHub {
                owner = "CodSpeedHQ";
                repo = "codspeed-rust";
                rev = "v${version}";
                hash = "sha256-q5xsZ8KHuC/Qm+o4xcWbW9Y9VrxHZ+/AxUO8TYEbE74=";
              };

              useFetchCargoVendor = true;
              cargoHash = "sha256-Ance7Hfl0EOmMfZf3ZqvawrK7scot7WpefLtemHKb+U=";

              nativeBuildInputs = with super; [
                curl
                pkg-config
              ];

              buildInputs =
                with super;
                [
                  curl
                  libgit2
                  openssl
                  zlib
                ]
                ++ lib.optionals stdenv.hostPlatform.isDarwin [
                  darwin.apple_sdk.frameworks.Security
                ];

              cargoBuildFlags = [ "-p=cargo-codspeed" ];
              cargoTestFlags = cargoBuildFlags;
              checkFlags = [
                # requires an extra dependency, blit
                "--skip=test_package_in_deps_build"
              ];

              env = {
                LIBGIT2_NO_VENDOR = 1;
              };
            };
          })
        ];
      };

      rust-bin = pkgs.rust-bin.fromRustupToolchainFile ./rust-toolchain.toml;

      clippy-reviewdog-filter = pkgs.rustPlatform.buildRustPackage {
        pname = "clippy-reviewdog-filter";
        version = "${inputs.clippy-reviewdog-filter-src.shortRev}";

        src = inputs.clippy-reviewdog-filter-src;

        cargoHash = "sha256-pGkpgwCNXxKzoWuRIUSgXCJ2+PzrvD8voxtkDvWIazc=";
      };
    in
    {
      devShells.${system}.default = pkgs.mkShell {
        name = "ltrait";

        buildInputs = with pkgs; [
          rust-bin

          cargo-nextest

          # bench
          gnuplot
        ];
      };

      packages.${system} = {
        ci = pkgs.buildEnv {
          name = "ci";
          paths = with pkgs; [
            rust-bin

            cargo-nextest
            typos

            # bench
            gnuplot
            cargo-codspeed
          ];
        };
        review = pkgs.buildEnv {
          name = "review";
          paths = with pkgs; [
            rust-bin

            cargo-nextest
            typos

            reviewdog

            clippy-reviewdog-filter
          ];
        };
      };
    };
}