logicng 0.1.0-alpha.3

A Library for Creating, Manipulating, and Solving Boolean Formulas
Documentation 
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31

WHITESPACE = _{ " " | "\t" | "\r" | "\n" }

pseudo_boolean = { SOI ~ equivalence? ~ EOI }
equivalence = { implication ~ ("<=>" ~ implication)* }
implication = { disjunction ~ ("=>" ~ disjunction)* }
disjunction = { conjunction ~ ("|" ~ conjunction)* }
conjunction = { lit ~ ("&" ~ lit)* }
lit = { comparison | simp }
simp = { not* ~ ( literal | constant | "(" ~ equivalence ~ ")") }
comparison = { mul ~ ( (add | sub) ~ mul)* ~ comp_type ~ number }
mul = { (number ~ "*")? ~ literal }

literal = ${ not? ~ var_name }
var_name = @{ (ASCII_ALPHANUMERIC | "_" | "@") ~ (ASCII_ALPHANUMERIC | "_")* }
number = @{ "-"? ~ ASCII_DIGIT+ }

constant = { verum | falsum }
verum = @{ "$true" }
falsum = @{ "$false" }

add = @{ "+" }
sub = @{ "-" }

comp_type = { eq | le | lt | ge | gt }
eq = @{ "=" }
le = @{ "<=" }
lt = @{ "<" }
ge = @{ ">=" }
gt = @{ ">" }

not = @{ "~" }